Jump to content

Welcome to the new Traders Laboratory! Please bear with us as we finish the migration over the next few days. If you find any issues, want to leave feedback, get in touch with us, or offer suggestions please post to the Support forum here.

  • Welcome Guests

    Welcome. You are currently viewing the forum as a guest which does not give you access to all the great features at Traders Laboratory such as interacting with members, access to all forums, downloading attachments, and eligibility to win free giveaways. Registration is fast, simple and absolutely free. Create a FREE Traders Laboratory account here.

Tradewinds

Bar Countdown Timer

Recommended Posts

Here is a count down timer for Easy Language that only works on an intraday chart. I hacked up that other code, and stripped out a lot of stuff. I got rid of a couple of function calls, and changed where the countdown display is located on the chart. I put it right next to the price bar. That's where I want it.

 

	{NAME:  	BarCountdownTimer

TYPE:	Indicator
Modified code originally created by	Bill Conley (AKA Kahuna)

https://www.tradestation.com/Discussions/Profile.aspx?Member_ID=2786}


inputs:
AlertPct(15);  // (0->100) Change color when this percentage of the bar remains

var:
LastBar(False),
TxtStr(""),		// Text String  
TxtID(text_new(date,time,close, " ")),		// Text Object Reference
dtEndTime(0),	// EndTime for Bar
dtTimeLeft(0),	// Time Left in Bar
dtBarTime(0),	// Total Time in Bar
BarLeftPct(0),	// Percent of Bar Remaining
MinDayInv(1/1440)	// One Min portion of day
;

const:
{ Display Options }
cDispRaw(2),		// Option to display Time/Tick/Vol Values
{ Bar Types }
cMinute(1)		 	// Intraday (Minute) Chart
;

var: CntrHeight(0);

{== Initialization ===================================================}

once begin
	// Check for valid chart
	if BarType <> 1	// Intraday (Minute) Chart
	then RaiseRunTimeError(
		"This code only works on Intraday chart");
	if AlertPct > 100 or AlertPct < 0 then
		RaiseRunTimeError("The AlertPct input must be set between 0 and 100");
		// Calc Total Time for Bar
			dtBarTime = MinDayInv * BarInterval;
  	end;

{== Calculations ====================================================}

LastBar = D = _LastCalcDate and T = _LastCalcTime;

if LastBar then begin // Only display in real-time
	Text_SetLocation(TxtID, D, T, (H+L)/2); // Set Text Location
	Text_SetStyle(TxtID, 0, 2) ; // Left & Centered 

	If BarStatus(1) = 2 then // BarStatus determines whether the bar is at open or close: 2 = close
		dtEndTime = ComputerDateTime + dtBarTime;			
	   	if dtEndTime <> 0 then begin
			dtTimeLeft = dtEndTime - ComputerDateTime; // Calc Time Left & Pct. Left
			BarLeftPct = (dtTimeLeft / dtBarTime) * 100;
			TxtStr = "      " + FormatTime("m:ss", dtTimeLeft); // Format the text
			End
		Else
			TxtStr = "Syncing...";

	text_setstring(TxtID, TxtStr);

	if BarLeftPct < AlertPct then 
		text_SetColor(TxtID, Red) // Use Alert Color
	Else text_SetColor(TxtID, Blue);		

End;

Share this post


Link to post
Share on other sites

It looks like TS version 9 has a new way to deal with forcing code to run, which affects countdown timers. Here is a new countdown timer.

 

{ _TimerExample4

v1.0	8 August 2011

Designed for TradeStation 9

This code is a simple bar countdown timer for minute bars.
}


using elsystem;

vars:	int TXID(0),

	IntrabarPersist Countdown_Text("  time"),

	IntrabarPersist mins(0), IntrabarPersist secs(0),
	IntrabarPersist mins_str(""), IntrabarPersist secs_str(""),

	IntrabarPersist Guess(true),

	Countdown_seconds(1),

	Timer Timer1(null);


//This is the Timer event.  Note that we've seperated out the 'time left in bar' calculation,
// and the 'display text' calculation into their own methods.  And then we call them from 
// this event.  This is good coding practice.
method void Timer1_Elapsed( Object sender, TimerElapsedEventArgs args ) 
begin
Calc_Time_Remaining();	//Calculate the amount of time remaining

Display_Text();			//Display the amount of time remaining
end;


//Calculate the amount of time remaining in the bar
// This is reasonably complex, but isn't particularly relevant to how the Timer object works
// so you don't need to understand it
method void Calc_Time_Remaining()
begin
//If its the end of a bar then set the countdown to the bar interval
if BarStatus(1) = 2 then begin
	mins = BarInterval;
	secs = 0;

	Guess = false;

	//We're turning the time off and on here just to sync it correctly with the bar end
	Timer1.Enable = false;
	Timer1.Enable = true;
end
//This is our first guess at the bar time, before we have a bar end to sync properly.
// It uses your computer clock to work out roughly how much time is left in a bar.
else if Guess then begin
	mins = BarInterval - Mod(MinutesFromDateTime(ComputerDateTime), BarInterval);
	secs = 60 - SecondsFromDateTime(ComputerDateTime);
	if secs = 60 then secs = 0;
	if secs > 0 then mins = mins - 1;
end
//Countdown our timer
else begin
	secs = secs - Countdown_seconds;
	if secs < 0 then begin
		mins = mins - 1;
		secs = 59;
	end;
end;

//Set our Countdown_Text variable to the correct string
mins_str = NumToStr(mins, 0);
secs_str = NumToStr(secs, 0);
if strlen(secs_str) = 1 then secs_str = "0" + secs_str;
Countdown_Text = "  " + mins_str  +":" + secs_str;
end;



//Display our countdown text
method void Display_Text()
begin
Text_SetString(TXID, Countdown_Text);
Text_SetLocation(TXID, date, time, Close);
Text_SetStyle(TXID, 0, 2);
end;



//This author uses 'once' to initialize objects.  Other authors may use 
// AnalysisTechnique_Initialize, or a component dragged and dropped from the 
// ToolBox.  All approaches are equally valid, they are just down to the 
// authors style.
once
begin
//Create the Timer, set it to update every second, but don't start it yet
Timer1 = new elsystem.Timer;
Timer1.Interval = Countdown_seconds * 1000;
Timer1.Elapsed += Timer1_Elapsed;

//Create the text to display the countdown	
TXID = Text_New(date, time, close, Countdown_Text);
end;


//When the first real-time tick arrives...
if GetAppInfo(aiRealTimeCalc) = 1 then begin
//...start the Timer
Timer1.Enable = true;

//Set the amount of time left in a bar at the end of every bar
if BarStatus(1) = 2 then begin
	Calc_Time_Remaining();
end;
end;

Display_Text();

Share this post


Link to post
Share on other sites

I modified the above code. I didn't like the code trying to guess how much time was left in the first bar, so I removed that. And I added text coloring to make the counter red when there is only 5 seconds left in the bar. Also changed the display from the close to the HL2 so it's not jumping around as much, and added some spacing to push it further to the right of the bar.

 

 

 

{ This code is a modified version of _TimerExample4

v1.0	8 August 2011

Designed for TradeStation 9

This code is a simple bar countdown timer for minute bars.
}

using elsystem;

vars: TxtID(0),	IntrabarPersist DisplayTxt(" "), IntrabarPersist mins(0), IntrabarPersist secs(0),
	IntrabarPersist mins_str(""), IntrabarPersist secs_str(""),

	IntrabarPersist FrstCalc(true),

	Timer Timer1(null);

method void Timer1_Elapsed( Object sender, TimerElapsedEventArgs args ) 
begin
Calc_Time_Remaining();	//Call Subroutine that calculates the time remaining
Display_Text();			//Call Subroutine that displays time remaining
end;

//Calculate the amount of time remaining in the bar
// This is reasonably complex, but isn't particularly relevant to how the Timer object works
// so you don't need to understand it
method void Calc_Time_Remaining()
begin
//If its the end of a bar then set the countdown to the bar interval
if BarStatus(1) = 2 then begin
	mins = BarInterval;
	secs = 0;

	FrstCalc = false;

	//Turning time off and back on to sync it with the bar end
	Timer1.Enable = false;
	Timer1.Enable = true;
end
//Countdown our timer
else if FrstCalc = false then begin
	secs = secs - 1;
	if secs < 0 then begin
		mins = mins - 1;
		secs = 59;
	end;
	DisplayTxt = "       " + mins_str  +":" + secs_str;
End
//First approximation of bar time, before end of bar sync.
// It uses your computer clock to work out roughly how much time is left in a bar.
else begin
	//mins = BarInterval - Mod(MinutesFromDateTime(ComputerDateTime), BarInterval);
	//secs = 60 - SecondsFromDateTime(ComputerDateTime);
	//if secs = 60 then secs = 0;
	//if secs > 0 then mins = mins - 1;
	DisplayTxt = "Syncing...";
end;


//Set our DisplayTxt variable to the correct string
mins_str = NumToStr(mins, 0);
secs_str = NumToStr(secs, 0);
if strlen(secs_str) = 1 then secs_str = "0" + secs_str;
end;



//Display our countdown text
method void Display_Text()
begin
if secs <= 5 then 
		text_SetColor(TxtID, Red) // Use Alert Color
	Else text_SetColor(TxtID, Blue);
Text_SetString(TxtID, DisplayTxt);
Text_SetLocation(TxtID, D, T, (H+L)/2);
Text_SetStyle(TxtID, 0, 2);
end;

once
begin
//Create the Timer, set it to update every second, but don't start it yet
Timer1 = new elsystem.Timer;
Timer1.Interval = 1 * 1000;
Timer1.Elapsed += Timer1_Elapsed;

//Create the text to display the countdown	
TxtID = Text_New(date, time, (H+L)/2, DisplayTxt);
end;

//When the first real-time tick arrives...
if GetAppInfo(aiRealTimeCalc) = 1 then begin
//...start the Timer
Timer1.Enable = true;

//Set the amount of time left in a bar at the end of every bar
if BarStatus(1) = 2 then begin
	Calc_Time_Remaining();
end;
end;

Display_Text();

Share this post


Link to post
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.
Note: Your post will require moderator approval before it will be visible.

Guest
Reply to this topic...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.


  • Topics

  • Posts

    • Back in the early 2000s, Netflix mailed DVDs to subscribers.   It wasn’t sexy—but it was smart. No late fees. No driving to Blockbuster.   People subscribed because they were lazy. Investors bought the stock because they realized everyone else is lazy too.   Those who saw the future in that red envelope? They could’ve caught a 10,000%+ move.   Another story…   Back in the mid-2000s, Amazon launched Prime.   It wasn’t flashy—but it was fast.   Free two-day shipping. No minimums. No hassle.   People subscribed because they were impatient. Investors bought the stock because they realized everyone hates waiting.   Those who saw the future in that speedy little yellow button? They could’ve caught another 10,000%+ move.   Finally…   Back in 2011, Bitcoin was trading under $10.   It wasn’t regulated—but it worked.   No bank. No middleman. Just wallet to wallet.   People used it to send money. Investors bought it because they saw the potential.   Those who saw something glimmering in that strange orange coin? They could’ve caught a 100,000%+ move.   The people who made those calls weren’t fortune tellers. They just noticed something simple before others did.   A better way. A quiet shift. A small edge. An asymmetric bet.   The red envelope fixed late fees. The yellow button fixed waiting. The orange coin gave billions a choice.   Of course, these types of gains are rare. And they happen only once in a blue moon. That’s exactly why it’s important to notice when the conditions start to look familiar.   Not after the move. Not once it's on CNBC. But in the quiet build-up— before the surface breaks.   Enter the Blue Button Please read more here: https://altucherconfidential.com/posts/netflix-amazon-bitcoin-blue  Profits from free accurate cryptos signals: https://www.predictmag.com/ 
    • What These Attacks Look Like There are several ways you could get hacked. And the threats compound by the day.   Here’s a quick rundown:   Phishing: Fake emails from your “bank.” Click the link, give your password—game over.   Ransomware: Malware that locks your files and demands crypto. Pay up, or it’s gone.   DDoS: Overwhelm a website with traffic until it crashes. Like 10,000 bots blocking the door. Often used by nations.   Man-in-the-Middle: Hackers intercept your messages on public WiFi and read or change them.   Social Engineering: Hackers pose as IT or drop infected USB drives labeled “Payroll.”   You don’t need to be “important” to be a target.   You just need to be online.   What You Can Do (Without Buying a Bunker) You don’t have to be tech-savvy.   You just need to stop being low-hanging fruit.   Here’s how:   Use a YubiKey (physical passkey device) or Authenticator app – Ditch text message 2FA. SIM swaps are real. Hackers often have people on the inside at telecom companies.   Use a password manager (with Yubikey) – One unique password per account. Stop using your dog’s name.   Update your devices – Those annoying updates patch real security holes. Use them.   Back up your files – If ransomware hits, you don’t want your important documents held hostage.   Avoid public WiFi for sensitive stuff – Or use a VPN.   Think before you click – Emails that feel “urgent” are often fake. Go to the websites manually for confirmation.   Consider Starlink in case the internet goes down – I think it’s time for me to make the leap. Don’t Panic. Prepare. (Then Invest.)   I spent an hour in that basement bar reading about cyberattacks—and watching real-world systems fall apart like dominos.   The internet going down used to be an inconvenience. Now, it’s a warning.   Cyberwar isn’t coming. It’s here.   And the next time your internet goes out, it might not just be your router.   Don’t panic. Prepare.   And maybe keep a backup plan in your back pocket. Like a local basement bar with good bourbon—and working WiFi.   As usual, we’re on the lookout for more opportunities in cybersecurity. Stay tuned.   Author: Chris Campbell (AltucherConfidential) Profits from free accurate cryptos signals: https://www.predictmag.com/   
    • DUMBSHELL:  re the automation of corruption ---  200,000 "Science Papers" in academic journal database PubMed may have been AI-generated with errors, hallucinations and false sourcing 
    • Does any crypto exchanges get banned in your country? How's about other as Bybit, Kraken, MEXC, OKX?
    • Does any crypto exchanges get banned in your country? How's about other as Bybit, Kraken, MEXC, OKX?
×
×
  • Create New...

Important Information

By using this site, you agree to our Terms of Use.