Peak Volume Price

[ValueTrader 10]

I tried to add the PVP code (OEC EL) that POPSTOCKS kindly posted on TL, however it failed to compile.

 

I tinkered with the 'Counters' as this was where the error message was pointing to.

 

I can now get it to run, but it appears to be giving me the PVP of each bar.

 

When i compare it to my Volume @ price histogram it returns a differnet value.

 

Is this because it is giving me the Peak volume Price from when the indicator is added / enabled, and is only of use in real-time?

 

Any help would be greatly appreciated.

 

Vars: Counter(0),
Op(0), 
Ct(0), 
hh(0), 
f(0),
mintick(0);

Array: v[800](0), p[800](0);

mintick=minmove/pricescale;

If 1 = 1 then Ct =1+Ct;
If Date > Date[1] or Ct = 1 then begin
Op = Open-100;

For Counter = 1 to 800
begin
p[counter] = 0;
v[counter] = 0;
End;

End;

For Counter = 1 to 800
begin
p[counter] = (counter*mintick)+Op;

If Close = p[counter] then v[counter]= volume+v[counter];

End;

hh = highestarray(v,800);

if hh> hh[1] then f = close;

Plot1(f);

Edited January 18, 2011 by ValueTrader

[Tams 20]

...

Any help would be greatly appreciated.

 

please wrap the code with code tag. That's the # key at the top of the message window.

Unwrapped codes are difficult to read (and debug).

[Tams 20]

pls check your code...

this line does not make sense

 

If 1 = 1 then Ct =1+Ct;

[ValueTrader 10]

Thanks for the expediant reply Tams.

 

I see what you mean, I've checked back and all POPSTOCKS PVP codes, and other TL users veriants use it, but what it does i have no idea.

 

I'm learning EL as i go, and my only programing knowledge is BASIC from when i was a kid (20 years ago). I looks like a loop of some kind.

 

I've removed the line you hightlighted,

 

the PVP line follows the current price bar, and is not giving the correct signal.

 

I have a volume histogram on OEC, but this is set to the day volume and is not user adjustable (from OEC tech support)

 

So the VOL@price histogram give a rough PVP, but isnt session accurate a volume traded befor the cash open is also diplayed. Besides i find it distracting having to keep update a PVP line manually on my chart.

 

Thanks VT

[Tams 20]

I tried to add the PVP code (OEC EL) that POPSTOCKS kindly posted on TL, however it failed to compile.

...

 

can you supply a link to this reference?

there is no use re-inventing the wheel,

any discussion there will help.

[ValueTrader 10]

http://www.traderslaboratory.com/forums/218/open-ecry-wish-list-thread-5362-10.html#post57596 Edited January 18, 2011 by ValueTrader
incorrect link in original reply

[Tams 20]

http:////www.traderslaboratory.com/forums/218/open-ecry-wish-list-thread-5362-11.html

Thanks VT

 

see the # number at the top-right corner of the post ?

you have to right click at the # number to grab the link.

[ValueTrader 10]

ok, updated the link.

 

I'm still getting to grips with forum etiquete. Thanks for the pointers.

[Tams 20]

http://www.traderslaboratory.com/forums/218/open-ecry-wish-list-thread-5362-10.html#post57596

 

the problem is in OEC.

see post #107

[ValueTrader 10]

I've contaced OEC, any luck and i'll post the results.

 

Thanks

 

VT.

[ValueTrader 10]

Further to my PVP Problems, I tried out the another code from the TL site..

vars:         MyVolume(0),
	PriceDiff(0),
	StartPrice(0),
	PVPPrice(0),
	PVPVolume(0),
	V2VolLevel(0);	

Array:
	PVPVolArray[10000] (0);

MyVolume = Volume;

if date > date[1] then begin
	StartPrice = AvgPrice;
	For Value1 = 0 to 10000 Begin
		PVPVolArray[Value1] = 0;
	End;
	PVPVolArray[5000] = MyVolume;
	PVPPrice = AvgPrice;
	PVPVolume = MyVolume;
end;

If date = date[1] And StartPrice > 0 Then Begin
	Value2 = AvgPrice - StartPrice;
	V2VolLevel = 5000+(Value2*(1/(minmove/pricescale)));
	PVPVolArray[V2VolLevel] = PVPVolArray[V2VolLevel] + MyVolume;

	If PVPVolArray[V2VolLevel] > PVPVolume Then Begin
		PVPVolume = PVPVolArray[V2VolLevel];
		PriceDiff = 5000-V2VolLevel;
		PVPPrice = StartPrice - (PriceDiff*(minmove/pricescale));
	End;

End;

Plot1(PVPPrice, "PVP");
Plot2(PVPVolume, "PVPVolume"); 

 

I've turned off the tick-by tick update option, else the pvp line seems to follow the last price.

 

My question is, is this reliable? The reason i question it is that my volume histogram shows the price with the most volume traded at different level. Am i missing somthing here? i've Demo traded using it before running it live, and some signals using the code seem to be correct, then at other times it appears my histogram peak volume is the correct one!

[Tams 20]

Further to my PVP Problems, I tried out the another code from the TL site.....

 

you should always provide a link to your source...

1. give the original author credit

2. so that ppl can understand the background... instead of starting from nowhere.

[ValueTrader 10]

http://www.traderslaboratory.com/forums/f56/building-volumeprofile-indicator-easylanguage-7073.html#post79436

[BlowFish 10]

That looked mightily familiar for some reason. Mind you I wrote a big chunk of the PvP indicator for DBtina... actually I took a big chunk and made a small perfectly formed chunk

 

This works for me without ADE. It averages the data across the bar so you do not update it every bar (like Ensign and Jerry's original stuff) it does a couple of other funky things too like variable number of days, old pvp. It has some comments but was kind of 'lazy' code maybe that will help you get a handle

//
//	PvP Averaged across bar. Set update at end of bar true.
//	See PvP Tick Precise version also
//

Input:
	PlotOldPvP (false),
	NumberofDays (1);

vars:
	n(0),m(0),
	StartPrice(0),						// Price corresponding to first element of  array
	PVPPrice(0),
	PVPPrice1(0),
	PVPPeakVolume(0),
	PVPIndex(0),							//Index of the peak (highest) volume array element
	PVPArraySize(3000),						//Set to Array Size
	PVPArrayMid(1500);						//Set to Array Mid Point
Array:
	PVPVolArray[3000] (0);					//Make sure this matches Array Size


if BarNumber = 1 then n = NumberofDays - 1;			//Make sure to reset on first bar
if (date > date[1]) or BarNumber =	1  then begin			//initialise
	n = n + 1;
	if n = NumberofDays then		
	begin	

		For Value1 = 0 to PVPArraySize Begin
			PVPVolArray[Value1] = 0;
		End;
		StartPrice = l;
		PVPPrice1 = PVPPrice;
		PVPPrice = StartPrice;
		PVPPeakVolume = 0;
		PVPIndex = PVPArrayMid;
		//PVPVolArray[PVPIndex] = Volume;
		n = 0;
	end;
end; 

Value2 = l - StartPrice;				//price in relation to starting price
value2 = value2 * (1/(MinMove/PriceScale));		
Value2 = PVPArrayMid+Value2;
value3 = (h-l) * (1/(MinMove/PriceScale));       // number of ticks l -> h				
Value1 = Round(Value2,0);				//shouldnt be needed as not adding to average price 
for m = Value1 to value1 + value3
begin
	PVPVolArray[m] = PVPVolArray[m] + Volume / (value3+1);	// +1 as as zero ticks should be vol/1 one tick vol/2 etc.
	If PVPVolArray[m] > PVPPeakVolume Then begin		// new peak volume? save it
		PVPIndex = m;
		PVPPeakVolume = PVPVolArray[m];
		PVPPrice = StartPrice - ((PVPArrayMid - m)*minmove/PriceScale );
	end;
end;

Plot1(PVPPrice, "PVPavg");
if (PVPPrice1 > 0 and PlotOldPvP) then Plot2 (PVPPrice1, "PVP Yesterday");	

[ValueTrader 10]

Thanks BlowFish, You the man!

[Enigmatics 10]

That looked mightily familiar for some reason. Mind you I wrote a big chunk of the PvP indicator for DBtina... actually I took a big chunk and made a small perfectly formed chunk

 

This works for me without ADE. It averages the data across the bar so you do not update it every bar (like Ensign and Jerry's original stuff) it does a couple of other funky things too like variable number of days, old pvp. It has some comments but was kind of 'lazy' code maybe that will help you get a handle

//
//	PvP Averaged across bar. Set update at end of bar true.
//	See PvP Tick Precise version also
//

Input:
	PlotOldPvP (false),
	NumberofDays (1);

vars:
	n(0),m(0),
	StartPrice(0),						// Price corresponding to first element of  array
	PVPPrice(0),
	PVPPrice1(0),
	PVPPeakVolume(0),
	PVPIndex(0),							//Index of the peak (highest) volume array element
	PVPArraySize(3000),						//Set to Array Size
	PVPArrayMid(1500);						//Set to Array Mid Point
Array:
	PVPVolArray[3000] (0);					//Make sure this matches Array Size


if BarNumber = 1 then n = NumberofDays - 1;			//Make sure to reset on first bar
if (date > date[1]) or BarNumber =	1  then begin			//initialise
	n = n + 1;
	if n = NumberofDays then		
	begin	

		For Value1 = 0 to PVPArraySize Begin
			PVPVolArray[Value1] = 0;
		End;
		StartPrice = l;
		PVPPrice1 = PVPPrice;
		PVPPrice = StartPrice;
		PVPPeakVolume = 0;
		PVPIndex = PVPArrayMid;
		//PVPVolArray[PVPIndex] = Volume;
		n = 0;
	end;
end; 

Value2 = l - StartPrice;				//price in relation to starting price
value2 = value2 * (1/(MinMove/PriceScale));		
Value2 = PVPArrayMid+Value2;
value3 = (h-l) * (1/(MinMove/PriceScale));       // number of ticks l -> h				
Value1 = Round(Value2,0);				//shouldnt be needed as not adding to average price 
for m = Value1 to value1 + value3
begin
	PVPVolArray[m] = PVPVolArray[m] + Volume / (value3+1);	// +1 as as zero ticks should be vol/1 one tick vol/2 etc.
	If PVPVolArray[m] > PVPPeakVolume Then begin		// new peak volume? save it
		PVPIndex = m;
		PVPPeakVolume = PVPVolArray[m];
		PVPPrice = StartPrice - ((PVPArrayMid - m)*minmove/PriceScale );
	end;
end;

Plot1(PVPPrice, "PVPavg");
if (PVPPrice1 > 0 and PlotOldPvP) then Plot2 (PVPPrice1, "PVP Yesterday");	

 

Can somebody help me .....

 

This indicator was working just fine for weeks on my charts. All of the sudden it won't work when I use it on my AAPL chart. It still works fine on the SPY. Anyone got an idea how to fix this?

 

[johnnydaymon 11]

Can somebody help me .....

 

This indicator was working just fine for weeks on my charts. All of the sudden it won't work when I use it on my AAPL chart. It still works fine on the SPY. Anyone got an idea how to fix this?

 

 

Above code works fine ; format window , chart properties 10 , 15

Check for a bad workspace problem