Stop Trading Counter

[binthere 10]

hi guys,

using tradestation 8.8

I'm looking for a way to have my strategy stop trading for "x" amount of minutes after

"y" number of winning trades or

"z" number of loosing trades

thanks for your help!!

binthere

[ScottB 10]

Hi,

 

If you are using intraday time based charts, you can use the EasyLanguage reserved word BarInterval to count time in multiples of your chart inverval. You could also simply stop your stragegy for X bars. You can also access the PC clock to get the time that way.

 

There are reserved words for all the variables you mention in your question.

 

Best Regards,

Scott

[rkurzon 10]

How much experience do you have with EasyLanguage? You can use the PositionProfit function to count the losers and winners then when you reach the count use calctime to time it. Don't forget to re-set the count at the end of the day or session. If you like I can code it up for you (no charge) but if you are experienced then this info should answer your question. Glad to help if you want me to code it.

 

Randall

[binthere 10]

thank's for the response, i'm trying to do this baby steps, first making the strategy stop trading when a specific number of winners or loosers is hit but it seems it's not working

could someone look at the code and help me out to understand what i'm doing wrong?

thanks, binthere

  Quote

Input:

NumberWinningTrades( 111 ),

NumberLosingTrades ( 111 );

 

Vars:

WinTrades( 0 ),

LosTrades( 0 ),

tradeOn (true);

 

If time = 0 then

Wintrades = NumLosTrades ;

Lostrades = NumWinTrades ;

 

IF ( Wintrades >= NumberWinningTrades) or (LosTrades >= NumberLoosingTrades) then

tradeOn (false)

else

begin

 

//strategy entries

 

//strategy exits

[ScottB 10]

Hi,

 

If that is the actual code, you are missing Begin/End after If time = 0 but time isn't ever 0 (it the time at the end of the bar), so your initialization wouldn't ever happen. Use either the Once keyword or a bool variable like needInit and then once you have done your initialization set it equal false.

 

I also assume you are incrementing the winning/losing trade counters somewhere in your code.

[binthere 10]

Randall

well this is the first time i actually code a strategy and have no prior developing experience, i've been strugling to make this hapen if you could help me out coding it would greatly appreciate it!!

every word i've used in the above code has taken me for ever to understand it and try to implement it

cheers!!, binthere

[rkurzon 10]

There are many ways to do it but I slapped this together and it should do what you want.

Could probably be done a little neater but it does verify.

 

Input: NumberWinningTrades(111), NumberLosingTrades (111), TimeOutMin(15);

 

Vars: TradeOff(FALSE), StopTime(0), StartAgainTime(0), WinTrades(0), LoseTrades(0),

LCount(0), WCount(0);

 

LoseTrades = NumLosTrades;

WinTrades = NumWinTrades;

 

//reset win/lose and TradeOff here on start of new day or firstbar after maxbarsback

//I am resetting it on new day but you can reset with anything, session time, another calctime, etc., etc.

if currentbar = 1 or date <> date[1] then begin

TradeOff = FALSE;

WCount = 0;

LCount = 0;

end;

 

//track win/lose trade count

if LoseTrades > LoseTrades[1] then LCount = LCount +1;

if WinTrades > WinTrades[1] then WCount = WCount +1;

 

//set TradeOff to TRUE and StopTime to time when win/lose trades was exceeded

if (WCount >= NumberWinningTrades) or (LCount >= NumberLosingTrades) then begin

TradeOff = TRUE;

StopTime = time;

end;

 

//calculate time to start again (add TimeOutMin to StopTime)

StartAgainTime = calctime(StopTime, TimeOutMin);

 

//reset TradeOff to FALSE after TimeOutMin to allow trading again on the same day

//reset trade counters to zero also

if TradeOff = TRUE and time > StartAgainTime then begin

TradeOff = FALSE;

WCount = 0;

LCount = 0;

end;

 

//allow entries

if TradeOff = FALSE then begin

 

//strategy entries

 

end;

[binthere 10]

Randall, this is HUGE!!!!

thanks for your help!, i've been strugling for over a week to get to the code i had posted earlier... and to get to the code you did it would have taken me a gazillion years in a very frustrating journey.

i can't thank you enough for your help

cheers,, keep it spinning!

binthere

[rkurzon 10]

My pleasure. If you have any further difficulties feel free to let me know.

 

Regards, Randall

[rkurzon 10]

Well, binthere got back to me and said the code would not start trading again after the time out. That's what I get for not testing my code :crap:. Below it is fixed and tested :-). It will reset on a change in date or exceeding the win/loss amount and will not trade for the time out period after that change. There are other ways to reset it, such as session end, session start, a specific time, etc., etc.

 

I have included the code here as a simple system that buys on one bar and exits on the next. I have also included the code (at bottom of system code) I use for de-bugging with the expert commentary. Just set the "Comm" input to true and using the expert commentary you can click anywhere on the chart to see the values at the close of that bar. Many people may also use a print statement for de-bugging but I personally prefer to use the commentary.

 

All of this goes to show something that I learned a long time ago but foolishly failed to implement here- always, always check your code to make sure it is doing what you think. More often than not code looks great and might do what you think part of the time but check, re-check, and re-check again. I hate to imagine how many great ideas have been discarded because they were coded wrong and failed.

 

I apologize for the error. ELD attached, coded in TS 8.6

 

 

Input: NumberWinningTrades(5), NumberLosingTrades (5), TimeOutMin(5), Comm(FALSE);

 

Vars: TradeOff(FALSE), StopTime(0), StartAgainTime(0), WinTrades(0), LoseTrades(0),

LCount(0), WCount(0), MP(0);

 

LoseTrades = NumLosTrades;

WinTrades = NumWinTrades;

MP = marketposition;

 

 

//reset all on date change or first bar

//you could reset here for whatever you choose

if currentbar = 1 or date <> date[1] then begin

StopTime = time;

StartAgainTime = calctime(StopTime, TimeOutMin);

TradeOff = TRUE;

WCount = 0;

LCount = 0;

end;

 

//track win/lose trade count (note reset above and date = date[1])

//will not carry count over after date change- easy to change this

if date = date[1] then begin

if LoseTrades > LoseTrades[1] then LCount = LCount +1;

if WinTrades > WinTrades[1] then WCount = WCount +1;

end;

 

//set TradeOff to TRUE and StopTime to time when win/lose trades was exceeded

if (WCount >= NumberWinningTrades) or (LCount >= NumberLosingTrades) then begin

TradeOff = TRUE;

StopTime = time;

//calculate time to start again (add TimeOutMin to StopTime)

StartAgainTime = calctime(StopTime, TimeOutMin);

WCount = 0;

LCount = 0;

end;

 

//reset TradeOff

if TradeOff = TRUE and time >= StartAgainTime then TradeOff = FALSE;

 

//allow entries

if TradeOff = FALSE then begin

 

if MP = 0 then buy next bar at market;

 

end;

 

if MP = +1 then sell next bar at market;

 

 

//beging expert commentary code used for debugging

if Comm then begin

 

Vars: Str0(""),

Str1(""),

Str2(""),

Str3(""),

Str4(""),

String1("");

 

#BeginCmtryOrAlert

if CommentaryEnabled and AtCommentaryBar then begin

 

if TradeOff = TRUE then Str0 = "TRUE" else

Str0 = "FALSE";

 

String1 =

newline +

newline + " TimedTrades_Sys " +

newline +

newline + " Date = " + NumToStr(Date, 0) +

newline + " Time = " + NumToStr(Time, 0) +

newline + " Open = " + NumToStr(Open, 4) +

newline + " Close = " + NumToStr(Close, 4) +

newline + " High = " + NumToStr(High, 4) +

newline + " Low = " + NumToStr(Low, 4) +

newline +

newline + " MP = " + NumToStr(MP, 0) +

newline + " TradeOff = " + Str0 +

newline + " StopTime = " + NumToStr(StopTime, 0) +

newline + " StartAgainTime = " + NumToStr(StartAgainTime, 0) +

newline + " LoseTrades = " + NumToStr(LoseTrades, 2) +

newline + " WinTrades = " + NumToStr(WinTrades, 2) +

newline + " WCount = " + NumToStr(WCount, 2) +

newline + " LCount = " + NumToStr(LCount, 2) +

newline +

newline;

Commentary(String1);

end;

#end;

end;// comm end

TIMEDTRADES.ELDFetching info...

[binthere 10]

Randall, this is exactly what i needed for my strat

thank you for helping out the strugling newbies !!! :applaud:

regards, binthere

[rkurzon 10]

You are very welcome. I received a lot of help from a lot of people over the years and very honestly continue to receive help. This is one of the toughest professions in the world and at very least it could become just a little easier if we help one another. Feel free to ask anytime.

 

Regards, Randall