Demand Index by James Sibbet

[billm 10]

Has anyone coded the Demand Index by James Sibbet for use with real-time volume?

Those familiar with Humphrey Neill's 'Tape Reading and Market Tactics' may know of

Jim's work adapting buying power and selling pressure to commodity markets.

Thanks, BillM

[momentom 10]

BillM,

I was one of the early members of CompuTrac where Jim was a member too. I haven't looked at the formula for years, but now that volume is available intraday it must be useful again. Do you need the formula or are you looking for a coded indicator. If the fomer, I'll try and find my old CompuTrac papers.

[billm 10]

Thank you for the response, momentom. Small world, I too, was an early comutrac member, traded fx at clearer, member at chi exch. etc.

 

I have the hand calculator instructions Jim sent me but it has been many years since I did any programming (fortran) and consequently thought I would check if anyone knew of Jim's work and was willing to share.

[thrunner 10]

Re: Sibbet's Demand Index

 

{ James Sibbet's Demand Index Function }
{ Programmed by David Fenstemaker }
{ The Demand Index combines price and volume in }
{ such a way that it is often a leading indicator 
( of price change. }


Inputs: Length (NumericSeries);

Vars : WtCRatio(1), VolRatio(1), VolAvg(Volume),
BuyP(1), SellP(1), Sign(+1), Return(0),
WghtClose(Close), AvgTR(High - Low),
Constant(1), BuyPres(1), SellPres(1),
TempDI(1), DMIndx(1);

If CurrentBar = 1 then
Begin
VolAvg = Average(Volume, Length);
End;

Return = 0 ;

WghtClose = (High + Low + Close + Close) * 0.25;
AvgTR = Average (Highest (High, 2) - Lowest ( Low, 2), Length);
VolAvg = ((VolAvg [1] * (Length - 1)) + Volume) / Length;

If WghtClose <> 0 and WghtClose[1] <> 0 and
AvgTR <> 0 and VolAvg <> 0 then
Begin
	WtCRatio = (WghtClose - WghtClose[1]) / MinList(WghtClose,WghtClose[1]) ;
VolRatio = Volume / VolAvg;
Constant = ((WghtClose * 3) /AvgTR) * AbsValue (WtCRatio);
If Constant > 88 then Constant = 88;
Constant = VolRatio / ExpValue (Constant);

If WtCRatio > 0 then
Begin
	BuyP = VolRatio;
	SellP = Constant;
End
Else
Begin
	BuyP = Constant;
	SellP = VolRatio;
End;

BuyPres = ((BuyPres [1] * (Length - 1)) + BuyP) / Length;
SellPres = ((SellPres [1] * (Length - 1)) + SellP) / Length;

TempDI = +1;

If SellPres > BuyPres then
Begin
	Sign = -1;
	If SellPres <> 0 then TempDI = BuyPres / SellPres;
End
Else
Begin
	Sign = +1;
	If BuyPres <> 0 then TempDI = SellPres / BuyPres;
End;

TempDI = TempDI * Sign;
If TempDI < 0 then
DMIndx = -1 - TempDI
else
DMIndx = +1 - TempDI ;

Return = DMIndx {* 100.0} ;

End;

DemandIndex = Return ;

 

{ James Sibbet's Demand Index Indicator }
{ Programmed by David Fenstemaker }
{ The Demand Index combines price and volume in }
{ such a way that it is often a leading 
( indicator of price change. }

Inputs: Length(5);

Vars: DMIndx(0);

DMIndx = DeMandIndex (Length) ;

Plot1(DMIndx, "DMI") ;
Plot2(0, "Zero") ;