VIDYA by Tushar Chande

[Tams 20]

VIDYA - The Variable Index Dynamic Index

 

by Tushar Chande

 

 

VIDYA is basically an adaptive exponential moving average.

 

The adaptation speed is determined by market momentum, as measured by "AbsCMO",

the absolute value of the Chande Momentum Oscillator.

 

This indicator is described in Chapter 3 of Dr. Chande's book "The New Technical Trader".

 

 

VIDYA_(MultiCharts).pla

[Tams 20]

// Type : Function
// Name : VIDYA

Input: 
Price(numericseries), 
CMOLen(numeric), 
VIDYALen(numeric),
Speed(numeric);

Var: 
Cnt(0),
SumUp(0), 
SumDn(0), 
Diff(0),
VIDYAPri(0),
AbsCMO(0),
Const(0);

SumUp = 0;
SumDn = 0;

For Cnt = 0 to CMOLen-1 Begin
Diff = Price[Cnt] - Price[Cnt+1];
If Diff > 0 then SumUp = SumUp + Diff else SumDn=SumDn-Diff;
End;

AbsCMO = Speed*AbsValue((SumUp-SumDn)/(SumUp+SumDn));
Const = 2/(VIDYALen+1);

VIDYA = iff(Barnumber>VIDYALen,(Price*Const*AbsCMO) +
((1-AbsCMO*Const)*VIDYA[1]),Price);

 

 

 

// Type : Indicator
// Name : VIDYA

Input: 
Price(TypicalPrice), 
CMOLen(9), 
VIDYALen(12), 
UBandPct(1),
LBandPct(1),
Speed(1);

Var: 
PlotVal(0);

PlotVal = VIDYA(Price,CMOLen,VIDYALen, Speed);

If PlotVal > 0 then 
begin
Plot1(PlotVal,"VIDYA");
Plot2((1 + UBandPct*.01)*PlotVal,"Upper Band");
Plot3((1 - LBandPct*.01)*PlotVal,"Lower Band");
End;

[Tams 20]

additional information in:

 

ActiveTraderMag / June 2001 - "Measuring Trend Momentum".

 

S&C Magazine, Traders Tips / October 1995 - "Identifying Powerful Breakouts Early"

 

 

.

Edited May 24, 2009 by Tams

[Tams 20]

related thread:

CMI - Chande Momentum Indicator

http://www.traderslaboratory.com/forums/f46/cmi-chande-momentum-indicator-6013.html