Previous Day OHLC in OEC Via Easylanguage

[trader273 10]

Since everyone was so helpful the last time, I have one other question. I am trying to plot the Open, High, Low, Close of the previous day via the following code from MC:

variables:
Counter( 0 ),
YestOpen( 0 ),
TodaysOpen( 0 ),
YestHigh( 0 ),
TodaysHigh( 0 ),
YestLow( 0 ),
TodaysLow( 0 ),
YestClose( 0 ),
TodaysClose( 0 ) ;

if Date <> Date[1] then
begin
{ increment Counter to be sure enough data is processed - see comment below }
Counter = Counter + 1 ;
YestOpen = TodaysOpen ;
YestHigh = TodaysHigh ;
YestLow = TodaysLow ;
YestClose = Close[1] ;
TodaysOpen = Open ;
TodaysHigh = High ;
  	TodaysLow = Low ;
end
else
begin
if High > TodaysHigh then
	TodaysHigh = High ;
if Low < TodaysLow then
	TodaysLow = Low ;
end ;

if Counter >= 2 and BarType < 3 then { if at least one full day's data has been
processed and chart bar interval is daily, intra-day, or tick bar, then plot }
begin
Plot1( YestOpen, "YestOpen" ) ;
Plot2( YestHigh, "YestHigh" ) ;
Plot3( YestLow, "YestLow" ) ;
Plot4( YestClose, "YestClose" ) ;
end ;

However, in OEC (not sure if other data vendors are like this) products that trade on sunday (eg Bonds and Notes) the sunday trading is treated like an entire day. I want to use the information from friday, not sunday. I came across a pivot indicator that ignored the weekends, but when i tried to mesh that code with what I was using, I couldnt get it to compile. Once again, thanks for any help.

[Frank 10]

there are simple reserved words for this:

 

highd(0) = todays high

highd(1) = yesterdays high

highd(2) = high of 2 days ago

 

opend(0) = todays open

opend(1) = yesterdays open

 

 

etc.....

[Harlequin 10]

Does OEC support the ELCollections.dll

 

This is how I do it in Multicharts. You have a daily chart or scanner window with one indicator to save the values from the previous trading day and then another indicator reads the values on your intraday chart.

[Tams 20]

there are simple reserved words for this:

highd(0) = todays high

highd(1) = yesterdays high

highd(2) = high of 2 days ago

opend(0) = todays open

opend(1) = yesterdays open

etc.....

 

these are functions, not reserved words.

 

ie. someone wrote a script/"program" that perform those operations.

[Frank 10]

I admit I do not know enough about programming to know what exactly they are --- but I use Open Ecry and calling functions in the code editor on the OEC platform requires an extra step vs the seamless way EasyLanguage does it. On the OEC platform -- to the coder anyway -- there is no extra step needed so there is no effective difference between whatever they are labeled vs the label 'reserved words'. Just trying to help the original poster, not trying to argue semantics.

[Tams 20]

I did not mean to be picky. Please do not take it as a challenge. I merely wanted to clarify.

 

 

A reserved word (also called keyword) is a "command/operation" that is built-in to the program.

 

eg. High, print, array, text, etc.

 

 

A function is a little "program", written with the reserved words, to perform certain operation.

 

eg. MACD, stochastic, RSI, average, etc.

 

 

 

A function might, or might not be residing in your program.

If you haven't got it in your computer, you can get the code and install it.

 

However a reserved word is built-in to your program.

If your program haven't got that keyword, then that means your program does not support that keyword. There is no way to get that into your computer.

 

e.g. some of the keywords in MultiCharts are not available in Tradestation or OEC.

[Frank 10]

Tams,

 

I am just curious -- is there a way to tell if its a keyword or a function? I mean, you do you know opend(0) is not just a keyword in the world of Open Ecry? thx in advance.

[Frank 10]

I am interested because I noted this in another thread (note that I am a programming ignoramus so I just have to figure things out without really knowing what is going on under the hood)

 

http://www.traderslaboratory.com/forums/f218/functions-in-oec-difft-than-ts-5513.html

[Tams 20]

Tams,

I am just curious -- is there a way to tell if its a keyword or a function? I mean, you do you know opend(0) is not just a keyword in the world of Open Ecry? thx in advance.

 

 

With MultiCharts, there is a dictionary in the PowerEditor.

If I right click on a word, it will tell me whether it is a keyword, function, or a variable.

 

I have never used OEC. You might have to check the OEC manual for a list of keywords.

 

For Tradestation, you can download this free book:

EasyLanguage® Functions & Reserved Words Reference

It lists (and explains) all the keywords, plus all the functions that are already loaded in the program.

https://www.tradestation.com/support/books/default.aspx#easylanguage

Edited March 23, 2009 by Tams

[Sherlock 10]

yesterday high & low, last weeks high and low, this weeks open and todays open in EL TS2000i:

 

If changing the value of weeknumberhighlow from 1 to 0 then it will be the high and low of the current week up until today (handy after Christmas)

 

set it up as an indicator, you'll need 10 days history

 

prcescale the same as the symbol and update it not at every tick: so'll you will have to wait until the first bar is completed. Otherwise with every tick you get some annoying screenflicker.

 

Make sure to have a bit of space on the right side of your prices that's where the lines will appear.

 

enjoy

 

Sherlock

 

paste=====>

 

 

Inputs:

lineColorOpenDay(darkGreen), {yesterdays close}

lineColorHighDay(Blue), {yesterdays high}

lineColorLowDay(Red), {yesterdays low}

lineStyleDay(tool_Solid), {Tool_Solid,Tool_Dotted, Tool_Dashed, Tool_Dashed2, Tool_Dashed3}

lineSizeDay(0), {thickness of line 0 - 6, if larger than 0 then dotted, dashed etc will not work}

lineColorOpenWeek(darkGreen), {this weeks open}

lineColorHighWeek(darkBlue), {this weeks high}

lineColorLowWeek(darkRed), {this weeks low}

lineStyleWeek(tool_Dotted), {Tool_Solid,Tool_Dotted, Tool_Dashed, Tool_Dashed2, Tool_Dashed3}

lineSizeWeek(0), {thickness of line 0 - 6, if larger than 0 then dotted, dashed etc will not work}

weekNumberHighLow(1), {when history is short last week is no good, 1 = last week, 0 = this week}

displaceLine(1); {displacing will only work on minute and daily charts, not on tick charts :-( }

 

Variables:

maxpts(6),

count(0),

dateOK(True),

lastDisplayTime (2359);

 

Arrays:

level[6](0),

lineID[6](0),

lineColor[6](0),

lineStyle[6](0),

lineSize[6](0);

 

If lastBarOnChart then

begin

{delete the lines - they are overlapping the old bars}

for count = 1 to maxpts

begin

if Level[Count] <> 0 then

begin

TL_delete(LineID[Count]);

end;

end;

{initialise values - unfortunately they'll have to be re-initialised}

Level[1] = OpenD(0);

Level[2] = LowD(1);

Level[3] = HighD(1);

Level[4] = OpenW(0);

Level[5] = LowW(weekNumberHighLow);

Level[6] = HighW(weekNumberHighLow);

 

LineColor[1] = lineColorOpenDay;

LineColor[2] = lineColorLowDay;

LineColor[3] = lineColorHighDay;

LineColor[4] = lineColorOpenWeek;

LineColor[5] = lineColorLowWeek;

LineColor[6] = lineColorHighWeek;

 

LineStyle[1] = lineStyleDay;

LineStyle[2] = lineStyleDay;

LineStyle[3] = lineStyleDay;

LineStyle[4] = lineStyleWeek;

LineStyle[5] = lineStyleWeek;

LineStyle[6] = lineStyleWeek;

 

LineSize[1] = lineSizeDay;

LineSize[2] = lineSizeDay;

LineSize[3] = lineSizeDay;

LineSize[4] = lineSizeWeek;

LineSize[5] = lineSizeWeek;

LineSize[6] = lineSizeWeek;

 

{if the bar is minutes then the trednlines do not have to go back all the way to the price bar.}

{unfortunately this only works with minute bars and not with tick bars}

if dataCompression = 1 then

value1 = displaceLine * barInterval

else

value1 = 0;

value2 = calctime(lastCalcTime , value1);

 

{need to check if the bar gets displaced beyond 2400 because then it plots on YESTERDAY's bars}

if value2 >= 2358 then value2 = 2358 ;

 

{now draw the lines}

for Count = 1 to maxpts

begin

{ fill the array with the TL parameters for deleting it later and plot the new trendline at the same time}

LineID[Count] = TL_New( Date,value2 , Level[count], Date, lastDisplayTime, Level[count]);

{complete the TL: set the trendline display parameters}

TL_SetColor(LineID[Count], LineColor[count]);

TL_SetStyle(LineID[Count], LineStyle[count]);

TL_SetSize(LineID[Count],lineSize[Count]);

TL_SetExtRight(LineID[Count], true );

end;

end;

 

<=======end paste

[HerveM 10]

Hi all,

 

code very useful and very educational thank you very much :thumbs up:

 

I would like to know how to add a text at the right of the screen (to specify what is the line) ?

 

Thanks in advance.