Finding Globex High and Low in Easylanguage

[trader273 10]

I was wondering if someone could help me out. I'm using OEC and trying to write a code that will draw a line for the globex high and globex low. I got it drawing from midnight, but just can't figure out how to get it when globex officially re-opens. EG 4:30pm EST for the ES as opposed to midnight. Any help is appreciated.

[Tams 20]

if you post the code, I can polish it for you.

[trader273 10]

Here's what I currently have:

 

Inputs: 
Globex_Start(0000), GLOBEX_END(930);

vars:
G_H(0), G_L(0);



//BEGIN CALCULATION OF GLOBEX HIGH AND LOW //
If Time=Globex_Start then begin
G_H=High;G_L=Low;
end;

If Time> Globex_Start and Time<=Globex_End then begin
If High>G_H then G_H=High;
if Low< G_L then G_L=low;
end;
//END CALCULATION OF GLOBEX HIGH AND LOW //



Plot1(G_H,"G-High");
Plot2(G_L,"G-Low");

 

This one gives me the high and low from midnight, I can't seem to figure out how to tell it to go the previous day and look to see if a low or high was there.

[Tams 20]

is your chart on 24hr session?

[trader273 10]

is your chart on 24hr session?

 

yes it is. Can change that if necessary.

[Tams 20]

you can declare a set of variables for the morning session, and a set of variables for the evening session.

 

e.g.

 

var:

G_morn_H(0),

G_morn_L(0),

 

G_even_H(0),

G_even_L(0);

 

then assign the respective highs and lows to the respective variables.

then plot the max of the 2 high variables, and the min of the 2 low variables.

 

 

This is the idea.

I will throw something together later tonight.

[trader273 10]

I'll give that a try as well. Im pretty much self taught in EL, so I appreciate any help I can get, thanks!

[sevensa 10]

Here is my version I am using. It is most likely not the best way of doing it as I am not a very efficient programmer and it is not 100% there. The minute between 23:59 and midnight is ignored, so you have a small chance of missing the high/low if it is made during that minute. I am only using it on time based charts, but I think it should work on tick and volume based charts too.

 

inputs:
StartTime1	(1530),
EndTime1	(2359),
StartTime2	(0000),
EndTime2	(0830),
PlotStartTime	(0830),
PlotEndtime	(1515),
TLSize		(1),
TLStyle	(1),
ONH_Color	(red),
ONL_Color	(green);


variables:
ON_High(0),
Plot_High(0),
ON_Low(999999999),
Plot_Low(0),
TL_ON_High(0),
TL_ON_Low(0),
ONH_Txt(0),
ONL_Txt(0),
TextStyleHoriz(1),	 	
TextStyleVert(1);		

If Time > PlotStartTime and Time[1] <= PlotStartTime then 
begin
Plot_High = ON_High;
Plot_Low = ON_Low;
ON_High = 0;
ON_Low = 999999999;
end;

if (Time >= StartTime1 and Time <= Endtime1) or (Time >= StartTime2 and Time <= EndTime2)  then
begin
if High > ON_High then ON_High = High; 
if Low < ON_Low then	On_Low = Low;
end ;

if Time > PlotStartTime then 
begin
TL_ON_High = TL_New(Date, PlotStartTime, Plot_High, Date, PlotEndTime, Plot_High);
	TL_SetColor(TL_ON_High, ONH_Color);
	TL_SetSize(TL_ON_High, TLSize);	
	TL_SetStyle(TL_ON_High, TLStyle);

TL_ON_Low = TL_New(Date, PlotStartTime, Plot_Low, Date, PlotEndTime, Plot_Low);
	TL_SetColor(TL_ON_Low, ONL_Color);
	TL_SetSize(TL_ON_Low, TLSize);	
	TL_SetStyle(TL_ON_Low, TLStyle);

ONH_Txt = Text_New(Date, PlotEndTime, Plot_High, "ONH");
	Text_SetStyle(ONH_Txt, TextStyleHoriz, TextStyleVert);	
	Text_SetColor(ONH_Txt, ONH_Color);

ONL_Txt = Text_New(Date, PlotEndTime, Plot_Low, "ONL");
	Text_SetStyle(ONL_Txt, TextStyleHoriz, TextStyleVert);	
	Text_SetColor(ONL_Txt, ONL_Color);
end;

[sevensa 10]

After posting the code above, I have been thinking about how to prevent the "missing minute" and I think the code below does this. The code above also assumed that the overnight session ends at the same time the regular session starts since I have coded it for the e-mini's. I think the code below will work if there is a gap between the overnight session end and regular session start.

 

I have not really tested this version other than briefly compared it to the previous one and there might be some logic errors in my thought process. Hopefully this will give you something to build on.

inputs:
StartTime	(1530),
EndTime	(0830),
PlotStartTime	(0830),
PlotEndtime	(1515),
TLSize		(1),
TLStyle	(1),
ONH_Color	(red),
ONL_Color	(green);


variables:
ON_High(0),
ON_Low(999999999),
TL_ON_High(0),
TL_ON_Low(0),
ONH_Txt(0),
ONL_Txt(0),
TextStyleHoriz(1),	 	
TextStyleVert(1),
Counter(0);

If Time > EndTime and Time[1] <= EndTime then 
begin
ON_High = 0;
ON_Low = 999999999; 
Counter = 1;

While Time[counter] > 0000 and date[counter] = Date begin
	if High[counter] > ON_High then ON_High = High[counter]; 
	if Low[counter] < ON_Low then On_Low = Low[counter];
	Counter = Counter + 1;
end;

While Time[counter] > StartTime begin
	if High[counter] > ON_High then ON_High = High[counter]; 
	if Low[counter] < ON_Low then On_Low = Low[counter];
	Counter = Counter + 1;
end;
end;

if Time > PlotStartTime then 
begin
TL_ON_High = TL_New(Date, PlotStartTime, ON_High, Date, PlotEndTime, ON_High);
	TL_SetColor(TL_ON_High, ONH_Color);
	TL_SetSize(TL_ON_High, TLSize);	
	TL_SetStyle(TL_ON_High, TLStyle);

TL_ON_Low = TL_New(Date, PlotStartTime, ON_Low, Date, PlotEndTime, ON_Low);
	TL_SetColor(TL_ON_Low, ONL_Color);
	TL_SetSize(TL_ON_Low, TLSize);	
	TL_SetStyle(TL_ON_Low, TLStyle);

ONH_Txt = Text_New(Date, PlotEndTime, ON_High, "ONH");
	Text_SetStyle(ONH_Txt, TextStyleHoriz, TextStyleVert);	
	Text_SetColor(ONH_Txt, ONH_Color);

ONL_Txt = Text_New(Date, PlotEndTime, ON_Low, "ONL");
	Text_SetStyle(ONL_Txt, TextStyleHoriz, TextStyleVert);	
	Text_SetColor(ONL_Txt, ONL_Color);
end;

[BlowFish 10]

Here's a possibility rather than dividing the session in two it uses a flag for moving in to and out of globex hours. Just edited the original code and didn't test it but should work (or only need a minor tweak).

 

Inputs: 
Globex_Start(1615), GLOBEX_END(930);

vars:
G_H(0), G_L(0), Globex(false);

if not Globex and Time >= Globex_Start then begin
G_H=High; G_L=Low;
Globex = True;
end;

If Globex and Time >= GLOBEX_END then
Globex = false;

If Globex then begin	
If High>G_H then G_H=High;
if Low< G_L then G_L=low;
end;

Plot1(G_H,"G-High");
Plot2(G_L,"G-Low");

[sevensa 10]

Here's a possibility rather than dividing the session in two it uses a flag for moving in to and out of globex hours. Just edited the original code and didn't test it but should work (or only need a minor tweak).

 

Inputs: 
Globex_Start(1615), GLOBEX_END(930);

vars:
G_H(0), G_L(0), Globex(false);

if not Globex and Time >= Globex_Start then begin
G_H=High; G_L=Low;
Globex = True;
end;

If Globex and Time >= GLOBEX_END then
Globex = false;

If Globex then begin	
If High>G_H then G_H=High;
if Low< G_L then G_L=low;
end;

Plot1(G_H,"G-High");
Plot2(G_L,"G-Low");

 

Hi Blowfish

 

This is certainly much simpler, but I don't think this will work. This line:

 

If Globex and Time >= GLOBEX_END then

Globex = false;

 

will set Globex to false at 16:15 because 16:15 > 9:30 (globex_end). So at the first bar after 16:15 (globex_start), Globex is set to true with the first if statement and then immediately set to false with the next if statement.

[BlowFish 10]

Hi Blowfish

 

This is certainly much simpler, but I don't think this will work. This line:

 

If Globex and Time >= GLOBEX_END then

Globex = false;

 

will set Globex to false at 16:15 because 16:15 > 9:30 (globex_end). So at the first bar after 16:15 (globex_start), Globex is set to true with the first if statement and then immediately set to false with the next if statement.

 

Your quite right I used >= so it would be OK with other chart types (tick,volume, range etc.) changing that to = will fix it for time based charts i think but it will not work for bar types that don't line up exactly with the start time and end time. Let me ponder a bit.

[sevensa 10]

Your quite right I used >= so it would be OK with other chart types (tick,volume, range etc.) changing that to = will fix it for time based charts i think but it will not work for bar types that don't line up exactly with the start time and end time. Let me ponder a bit.

 

Maybe if you change it to:

 

If Globex and Time >= GLOBEX_END and Time[1] < GLOBEX_END then

Globex = false;

 

it will work for non time based charts as well?

[BlowFish 10]

Inputs: 
Session_Start(930), Session_End(1615);

vars:
G_H(0), G_L(0), Globex(false);

If Globex and Time >= Session_Start and time < Session_End then
Globex = false;

if not Globex and Time >= Session_End then begin // Should only execute first tick of Globex session
G_H=High; G_L=Low;
Globex = True;
end;

If Globex then begin	
If High>G_H then G_H=High;
if Low< G_L then G_L=low;
end;

Plot1(G_H,"G-High");
Plot2(G_L,"G-Low");

 

Hows that? Might still be wrong as I don't have Multicharts to test on right now. (and I have tied my brain in a knot too but it seems plausible!)

 

It is looking for regular session first and resetting on regular session end. (I changed the variables to session start/end rather than globex start end as I find that easier to visualise.)

[BlowFish 10]

Maybe if you change it to:

 

If Globex and Time >= GLOBEX_END and Time[1] < GLOBEX_END then

Globex = false;

 

it will work for non time based charts as well?

 

That may well work too, I am not sure about tick and constant volume I think it might be possible to have two bars with the same time stamp.

[brownsfan019 17]

Good stuff here guys as this is something I am going to test out as well. Thanks for the contributions.

[sevensa 10]

 

Hows that? Might still be wrong as I don't have Multicharts to test on right now. (and I have tied my brain in a knot too but it seems plausible!)

 

It is looking for regular session first and resetting on regular session end. (I changed the variables to session start/end rather than globex start end as I find that easier to visualise.)

 

This one works like a charm and much to my dismay for the hours I have spent on my version, is much simpler too.

Maybe my version can be used as an example on how not to overcomplicate things...

[BlowFish 10]

This one works like a charm and much to my dismay for the hours I have spent on my version, is much simpler too.

Maybe my version can be used as an example on how not to overcomplicate things...

 

Excellent! I was probablly the worlds worst programmer when I started out (if thats any comfort). The first proper job I had after university they sent me to be re-trained on the stuff I was supposed to know. Like most things the way to get better at coding is to code. No surprises there then.

[trader273 10]

Thanks everyone for your help. I got the code that blowfish had to compile in MC, unfortunately it wont compile in OEC. I have attached the errors that it gives me. Anyone got any ideas?

 

[Tams 20]

change

 

if not Globex

 

to

 

if Globex = false

[trader273 10]

Awesome, got that to work.

[BlowFish 10]

Just out of interest are Globex extremes still good to trade against? I used too in the ES with fairly good effect. Not sure why I removed them from my charts to be honest. I guess there are so many lines that 'work' often enough to be useful. Are you using them as potential S/R areas? Maybe now I have the indicator I should watch them again!

[jonbig04 10]

Just out of interest are Globex extremes still good to trade against?[/quote

 

Hell yes. IMO

[brownsfan019 17]

Just out of interest are Globex extremes still good to trade against? I used too in the ES with fairly good effect. Not sure why I removed them from my charts to be honest. I guess there are so many lines that 'work' often enough to be useful. Are you using them as potential S/R areas? Maybe now I have the indicator I should watch them again!

 

BF - I watch those areas on the bonds and indexes for sure. If nothing else, good to know where the highest high and lowest low held in overnight hours. To me that shows that the bulls or bears were willing to step in right there and there's a chance they'll do it again.

 

As w/ anything, see how it works for you first.

[BlowFish 10]

Yeah they always 'worked' for me in the past. There are so many valid lines you can put on your charts that 'work' though. Confluence is always interesting and tends to add weight, for example if the globex high is at yesterdays POC and last weeks mid point.

 

Instinctively the Globex levels will be 'fresher' having just occurred but perhaps less significant as they tend to form on low(ish) volume. e.g A 3 day H/L represents a longer struggle with more protagonists.