Jump to content

Welcome to the new Traders Laboratory! Please bear with us as we finish the migration over the next few days. If you find any issues, want to leave feedback, get in touch with us, or offer suggestions please post to the Support forum here.

  • Welcome Guests

    Welcome. You are currently viewing the forum as a guest which does not give you access to all the great features at Traders Laboratory such as interacting with members, access to all forums, downloading attachments, and eligibility to win free giveaways. Registration is fast, simple and absolutely free. Create a FREE Traders Laboratory account here.

Tams

Adaptive CCI

By Tams, in Trading Indicators

Recommended Posts

Tams    20

Tams
Posted 

{Adaptive CCI
From the book 'Rocket Science for Traders' by John Ehlers
modified with new cycle measurement method from 'Cybernetic Analysis for Stocks and Futures'

mmillar, July 2004

Price   - the current price - only used by the Cycle Period measurement, not by the CCI calculation
Length   - used by the Cycle Period measurement - John Ehlers uses alpha but I have replaced it with the more intuitive Length, where alpha=2/(Length+1)
CycPart - allows you to change how much of the cycle period should be used in the CCI calculation - usually 1

}

Inputs:   Price((H+L)/2), Length(19), CycPart(1);

Vars:   oResult1(0), oResult2(0);

value1=_Oscillators(18, Price, Length, CycPart, 1, 0, 1, oResult1, oResult2);

Plot1(oResult1, "AdaptCCI");

 

_Oscillators function:

{A collection of oscillators by John Ehlers
by mmillar, July 2004

1-15 are taken from 'Cybernetic Analysis for Stocks and Futures'
16-18 are taken from 'Rocket Science for Traders' and updated using a new cycle period measurement method

This function calls the function '_CyclePeriod' to calculate the Dominant Cycle for use in adaptive strategies


Oscillator Types
  1 - Cyber Cycle
  2 - CG Oscillator
  3 - Relative Vigor Index (RVI)
  4 - Stochastic RSI
  5 - Stochastic Cyber Cycle
  6 - Stochastic CG
  7 - Stochastic RVI
  8 - Fisher Cyber Cycle
  9 - Fisher CG
  10 - Fisher RVI
  11 - Adaptive Cyber Cycle
  12 - Adaptive CG
  13 - Adaptive RVI
  14 - Sinewave Indicator
  15 - Laguerre RSI
  16 - Adaptive RSI
  17 - Adaptive Stochastic
  18 - Adaptive CCI

This function is called with
  OscType - one of the above
  Price   - some indicators can use a price input e.g. (H+L)/2, Close etc, otherwise this can be set to 0
  Length   - the length or period that you wish to measure.  In some instances John Ehlers uses 'alpha' as his
          input but I have standardised all inputs using Length and then converted, where necessary, with
          alpha=2/(Length+1)
  Length2   - this is a catch all used when an additional input variable is needed (just because everything is done in one function)
  RSILength, StocLength, WMALength - only used by Stochastic RSI (OscType=4)
  oResult1, oResult2 - are the results returned by the function
}


Inputs:   OscType(Numeric), Price(Numeric), Length(Numeric), Length2(Numeric),   {general inputs}
     RSILength(Numeric), StocLength(Numeric), WMALength(Numeric),          {only used by OscType=4}
     oResult1(NumericRef), oResult2(NumericRef);                         {results to return}

Vars:   alpha(0), 
     count(0), Num(0), Denom(0),
     Smooth(0), Cycle(0),             {for OscType=1, 5, 8, 11}
     CG(0),                        {for OscType=2, 6, 9, 12}
     RVI(0),                        {for OscType=3, 7, 10, 13}
     MaxVal(0), MinVal(0),            {for OscType=5-10}
     Period(0),                     {for OscType=11-18}
     Cycle1(0),                      {for OscType=11-18 but only used in 14}
     Smooth1(0),                     {for OscType=11-18 but only used in 11}
     DCPeriod(0), RealPart(0), ImagPart(0), DCPhase(0),   {for OscType=14}
     L0(0), L1(0), L2(0), L3(0),       {for OscType=15}
     vRSI(0), CU(0), CD(0),             {for OscType=15, 16}
     vStoch(0), HH(0), LL(0),          {for OscType=17}
     vCCI(0), Avg(0), MD(0), MPrice(0);   {for OscType=18}

If ( OscType=1 ) then Begin {Cyber Cycle}
  alpha=2/(Length+1);
  Smooth=(Price+2*Price[1]+2*Price[2]+Price[3])/6;
  Cycle=(1-0.5*alpha)*(1-0.5*alpha)*(Smooth-2*Smooth[1]+Smooth[2])+2*(1-alpha)*Cycle[1]-(1-alpha)*( 1-alpha)*Cycle[2];
  If currentbar<7 then Cycle=(Price-2*Price[1]+Price[2])/4;

  oResult1=Cycle;
  oResult2=Cycle[1];
end
else If ( OscType=2 ) then Begin {CG Oscillator}
  Num=0;
  Denom=0;
  For count=0 to Length-1 Begin
     Num=Num+(1+count)*Price[count];
     Denom=Denom+Price[count];
  end;
  If Denom<>0 then CG=-Num/Denom+(Length+1)/2;

  oResult1=CG;
  oResult2=CG[1];
end
else If ( OscType=3 ) then Begin {Relative Vigor Index}
  Value1=((Close-Open)+2*(Close[1]-Open[1])+2*(Close[2]-Open[2])+(Close[3]-Open[3]))/6;
  Value2=((High-Low)+2*(High[1]-Low[1])+2*(High[2]-Low[2])+(High[3]-Low[3]))/6;
  Num=0;
  Denom=0;
  For count=0 to Length-1 Begin
     Num=Num+Value1[count];
     Denom=Denom+Value2[count];
  end;
  If Denom<>0 then RVI=Num/Denom;

  oResult1=RVI;
  oResult2=RVI[1];
end
else If ( OscType=4 ) then Begin {Stochastic RSI}
  Value1=RSI(Close, RSILength)-Lowest(RSI(Close, RSILength), StocLength);
  Value2=Highest(RSI(Close, RSILength), StocLength)-Lowest(RSI(Close, RSILength), StocLength);
  If Value2<>0 then Value3=Value1/Value2;
  Value4=2*(WAverage(Value3, WMALength)-0.5);

  oResult1=Value4;
  oResult2=Value4[1];
end
else If ( OscType=5 ) then Begin {Stochastic Cyber Cycle}
  alpha=2/(Length+1);
  Smooth=(Price+2*Price[1]+2*Price[2]+Price[3])/6;
  Cycle=(1-0.5*alpha)*(1-0.5*alpha)*(Smooth-2*Smooth[1]+Smooth[2])+2*(1-alpha)*Cycle[1]-(1-alpha)*(1-alpha)*Cycle[2];
  If currentbar<7 then Cycle=(Price-2*Price[1]+Price[2])/4;

  MaxVal=Highest(Cycle, StocLength);
  MinVal=Lowest(Cycle, StocLength);
  If MaxVal<>MinVal then Value1=(Cycle-MinVal)/(MaxVal-MinVal);
  Value2=(4*Value1+3*Value1[1]+2*Value1[2]+Value1[3])/10;
  Value2=2*(Value2-0.5);

  oResult1=Value2;
  oResult2=0.96*(Value2[1]+0.02);
end
else If ( OscType=6 ) then Begin {Stochastic CG}
  Num=0;
  Denom=0;
  For count=0 to Length-1 Begin
     Num=Num+(1+count)*Price[count];
     Denom=Denom+Price[count];
  end;
  If Denom<>0 then CG=-Num/Denom+(Length+1)/2;

  MaxVal=Highest(CG, Length);
  MinVal=Lowest(CG, Length);
     If MaxVal<>MinVal then Value1=(CG-MinVal)/(MaxVal-MinVal);
  Value2=(4*Value1+3*Value1[1]+2*Value1[2]+Value1[3])/10;
  Value2=2*(Value2-0.5);

  oResult1=Value2;
  oResult2=0.96*(Value2[1]+0.02);
end
else If ( OscType=7 ) then Begin {Stochastic RVI}
  Value1=((Close-Open)+2*(Close[1]-Open[1])+2*(Close[2]-Open[2])+(Close[3]-Open[3]))/6;
  Value2=((High-Low)+2*(High[1]-Low[1])+2*(High[2]-Low[2])+(High[3]-Low[3]))/6;
  Num=0;
  Denom=0;
  For count=0 to Length-1 Begin
     Num=Num+Value1[count];
     Denom=Denom+Value2[count];
  end;
  If Denom<>0 then RVI=Num/Denom;

  MaxVal=Highest(RVI, Length);
  MinVal=Lowest(RVI, Length);
  If MaxVal<>MinVal then Value3=(RVI-MinVal)/(MaxVal-MinVal);
  Value4=(4*Value3+3*Value3[1]+2*Value3[2]+Value3[3])/10;
  Value4=2*(Value4-0.5);

  oResult1=Value4;
  oResult2=0.96*(Value4[1]+0.02);
end
else If ( OscType=8 ) then Begin {Fisher Cyber Cycle}
  alpha=2/(Length+1);
  Smooth=(Price+2*Price[1]+2*Price[2]+Price[3])/6;
  Cycle=(1-0.5*alpha)*(1-0.5*alpha)*(Smooth-2*Smooth[1]+Smooth[2])+2*(1-alpha)*Cycle[1]-(1-alpha)*(1-alpha)*Cycle[2];
  If currentbar<7 then Cycle=(Price-2*Price[1]+Price[2])/4;

  MaxVal=Highest(Cycle, Length2);
  MinVal=Lowest(Cycle, Length2);
  If MaxVal<>MinVal then Value1=(Cycle-MinVal)/(MaxVal-MinVal);
  Value2=(4*Value1+3*Value1[1]+2*Value1[2]+Value1[3])/10;
  Value3=0.5*Log((1+1.98*(Value2-0.5))/(1-1.98*(Value2-0.5)));

  oResult1=Value3;
  oResult2=Value3[1];
end
else If ( OscType=9 ) then Begin {Fisher CG}
  Num=0;
  Denom=0;
  For count=0 to length-1 Begin
     Num=Num+(1+count)*(Price[count]);
     Denom=Denom+(Price[count]);
  end;
  If Denom<>0 then CG=-Num/Denom+(Length+1)/2;

  MaxVal=Highest(CG, Length);
  MinVal=Lowest(CG, Length);
  If MaxVal<>MinVal then Value1=(CG-MinVal)/(MaxVal-MinVal);
  Value2=(4*Value1+3*Value1[1]+2*Value1[2]+Value1[3])/10;
  Value3=0.5*Log((1+1.98*(Value2-0.5))/(1-1.98*(Value2-0.5)));

  oResult1=Value3;
  oResult2=Value3[1];
end
else If ( OscType=10 ) then Begin {Fisher RVI}
  Value1=((Close-Open)+2*(Close[1]-Open[1])+2*(Close[2]-Open[2])+(Close[3]-Open[3]))/6;
  Value2=((High-Low)+2*(High[1]-Low[1])+2*(High[2]-Low[2])+(High[3]-Low[3]))/6;
  Num=0;
  Denom=0;
  For count=0 to Length-1 Begin
     Num=Num+Value1[count];
     Denom=Denom+Value2[count];
  end;
  If Denom<>0 then RVI=Num/Denom;

  MaxVal=Highest(RVI, Length);
  MinVal=Lowest(RVI, Length);
  If MaxVal<>MinVal then Value3=(RVI-MinVal)/(MaxVal-MinVal);
  Value4=(4*Value3+3*Value3[1]+2*Value3[2]+Value3[3])/10;
  Value5=0.5*Log((1+1.98*(Value4-0.5))/(1-1.98*(Value4-0.5)));

  oResult1=Value5;
  oResult2=Value5[1];
end
else If ( OscType=11 ) then Begin {Adaptive Cyber Cycle}
  alpha=2/(Length+1);
  Period=_CyclePeriod(Price, alpha, Cycle1, Smooth1);

  alpha=2/(Period+1);
  Cycle=(1-0.5*alpha)*(1-0.5*alpha)*(Smooth1-2*Smooth1[1]+Smooth1[2])+2*(1-alpha)*Cycle[1]-(1-alpha)*(1-alpha)*Cycle[2];
  If currentbar<7 then Cycle=(Price-2*Price[1]+Price[2])/4;

  oResult1=Cycle;
  oResult2=Cycle[1];
end
else If ( OscType=12 ) then Begin {Adaptive CG}
  alpha=2/(Length+1);
  Period=_CyclePeriod(Price, alpha, Cycle1, Smooth1);
  Value1=IntPortion(Period/2); {use half the cycle period}

  Num=0;
  Denom=0;
  For count=0 to Value1-1 Begin
     Num=Num+(1+count)*(Price[count]);
     Denom=Denom+(Price[count]);
  end;
  If Denom<>0 then CG=-Num/Denom+(Value1+1)/2;

  oResult1=CG;
  oResult2=CG[1];
end
else If ( OscType=13 ) then Begin {Adaptive RVI}
  alpha=2/(Length+1);
  Period=_CyclePeriod(Price, alpha, Cycle1, Smooth1);
  Value3=IntPortion((4*Period+3*Period[1]+2*Period[3]+Period[4])/20);

  Value1=((Close-Open)+2*(Close[1]-Open[1])+2*(Close[2]-Open[2])+(Close[3]-Open[3]))/6;
  Value2=((High-Low)+2*(High[1]-Low[1])+2*(High[2]-Low[2])+(High[3]-Low[3]))/6;
  Num=0;
  Denom=0;
  For count=0 to Value3-1 Begin
     Num=Num+Value1[count];
     Denom=Denom+Value2[count];
  end;
  If Denom<>0 then RVI=Num/Denom;

  oResult1=RVI;
  oResult2=RVI[1];
end
else If ( OscType=14 ) then Begin {Sinewave Indicator}
  alpha=2/(Length+1);
  Period=_CyclePeriod(Price, alpha, Cycle1, Smooth1);

  DCPeriod=IntPortion(Period);
  RealPart=0;
  ImagPart=0;
  For count=0 to DCPeriod-1 Begin
     RealPart=RealPart+Sine(360*count/DCPeriod)*(Cycle1[count]);
     ImagPart=ImagPart+Cosine(360*count/DCPeriod)*(Cycle1[count]);
  end;
  If AbsValue(ImagPart)>0.001 then DCPhase=Arctangent(RealPart/ImagPart);
  If AbsValue(ImagPart)<=0.001 then DCPhase=90*Sign(RealPart);
  DCPhase=DCPhase+90;
  If ImagPart<0 then DCPhase=DCPhase+180;
  If DCPhase>315 then DCPhase=DCPhase-360;

  oResult1=Sine(DCPhase);
  oResult2=Sine(DCPhase+45);
end
else If ( OscType=15 ) then Begin {Laguerre RSI}
  L0=(1-Length2)*Close+Length2*L0[1];
  L1=-Length2*L0+L0[1]+Length2*L1[1];
  L2=-Length2*L1+L1[1]+Length2*L2[1];
  L3=-Length2*L2+L2[1]+Length2*L3[1];

  CU=0;
  CD=0;
  If L0>=L1 then CU=L0-L1 else CD=L1-L0;
  If L1>=L2 then CU=CU+L1-L2 else CD=CD+L2-L1;
  If L2>=L3 then CU=CU+L2-L3 else CD=CD+L3-L2;
  If CU+CD<>0 then vRSI=CU/(CU+CD);

  oResult1=vRSI;
  oResult2=0;
end
else If ( OscType=16 ) then Begin {Adaptive RSI}   
  alpha=2/(Length+1);
  Period=_CyclePeriod(Price, alpha, Cycle1, Smooth1);

  CU=0;
  CD=0;
  For count=0 to (Period*Length2)-1 Begin
     If Close[count]-Close[count+1]>0 then CU=CU+(Close[count]-Close[count+1]);
     If Close[count]-Close[count+1]<0 then CD=CD+(Close[count+1]-Close[count]);
  end;
  If CU+CD<>0 then vRSI=100*CU/(CU+CD);

  oResult1=vRSI;
  oResult2=0;
end
else If ( OscType=17 ) then Begin {Adaptive Stochastic}
  alpha=2/(Length+1);
  Period=_CyclePeriod(Price, alpha, Cycle1, Smooth1);

  HH=High;
  LL=Low;
  For count=0 to IntPortion(Period*Length2)-1 Begin
     If High[count]>HH then HH=High[count];
     If Low[count]<LL then LL=Low[count];
  end;
  If HH-LL<>0 then vStoch=(Close-LL)/(HH-LL);

  oResult1=vStoch;
  oResult2=0;
end
else If ( OscType=18 ) then Begin {Adaptive CCI}
  alpha=2/(Length+1);
  Period=_CyclePeriod(Price, alpha, Cycle1, Smooth1);

  Value1=IntPortion(Period*Length2);
  MPrice=(High+Low+Close)/3;
  Avg=0;
  For count=0 to Value1-1 Begin
     Avg=Avg+MPrice[count];
  end;
  If Value1<>0 then Avg=Avg/Value1;
  MD=0;
  For count=0 to Value1-1 Begin
     MD=MD+AbsValue(MPrice[count]-Avg);
  end;
  If Value1<>0 then MD=MD/Value1;
  If MD<>0 then vCCI=(MPrice-Avg)/(0.015*MD);

  oResult1=vCCI;
  oResult2=0;
end;

_Oscillators=1;

 

_cycleperiod function

{Cycle Period Measurement
From the book 'Cybernetic Analysis for Stocks and Futures' by John Ehlers

mmillar, July 2004

This function is called with 
  Price   - the current price, such as (H+L)/2 or Close
  alpha   - the alpha (which is related to the measurement period/length)
  oCycle   - a return variable that is needed by some indicators
}


Inputs:   Price(numeric), alpha(numeric), oCycle(numericref), oSmooth(numericref);

Vars:   Smooth(0), Cycle(0), Q1(0), I1(0), DC(0),
     DeltaPhase(0), MedianDelta(0), InstPeriod(0), Period(0);

Smooth=(Price+2*Price[1]+2*Price[2]+Price[3])/6;
Cycle=(1-0.5*alpha)*(1-0.5*alpha)*(Smooth-2*Smooth[1]+Smooth[2])+2*(1-alpha)*Cycle[1]-(1-alpha)*(1 -alpha)*Cycle[2];
If currentbar<7 then Cycle=(Price-2*Price[1]+Price[2])/4;

Q1=(0.0962*Cycle+0.5769*Cycle[2]-0.5769*Cycle[4]-0.0962*Cycle[6])*(0.5+0.08*InstPeriod[1]);
I1=Cycle[3];

If Q1<>0 and Q1[1]<>0 then DeltaPhase=(I1/Q1-I1[1]/Q1[1])/(1+I1*I1[1]/(Q1*Q1[1]));
If DeltaPhase<0.1 then DeltaPhase=0.1;
If DeltaPhase>1.1 then DeltaPhase=1.1;
MedianDelta=Median(DeltaPhase, 5);

If MedianDelta=0 then DC=15 else DC=6.28318/MedianDelta+0.5;
InstPeriod=0.33*DC+0.67*InstPeriod[1];
Period=0.15*InstPeriod+0.85*Period[1];

oCycle=Cycle;
oSmooth=Smooth;
_CyclePeriod=Period;

Adaptive_CCI.gif.8b1f12826c065036210c034a328f2b00.gif

Share this post

Link to post
Share on other sites

BlowFish    10

BlowFish
Posted
Thanks for posting someone elses code from the Tradestation Forum.:haha:

 

Lots of people (Multicharts users for example) don't have access to TS forums, so having an alternate source is handy.

 

Just one thing Tams, this looks like it's a lot more than just a CCI, dont know if you can change the thread title.

Share this post

Link to post
Share on other sites

Jazz1964    10

Jazz1964
Posted
I am looking for working Adaptive CCI indicators for MetaTrader4.

Can somebody help me?

Would be great!

 

Cheers,

Jazz

 

Nobody have this adaptive CCI in Metatrader, or knows where to get it?

 

Best regards,

Jazz

Share this post

Link to post
Share on other sites

Tams    20

Tams
Posted
Lots of people (Multicharts users for example) don't have access to TS forums, so having an alternate source is handy.

 

Just one thing Tams, this looks like it's a lot more than just a CCI, dont know if you can change the thread title.

 

the first block of code is the indicator,

the other 2 are functions that the indicator calls.

Share this post

Link to post
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.
Note: Your post will require moderator approval before it will be visible.

Guest
Reply to this topic...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
Go To Topic Listing

  • Similar Content

  • Topics

  • Posts

    • analyst75
      Our latest Neteller VIPs: Adetoye Oyebanji, Isiaka Adekunle and Abiodun Lawanson

      By analyst75 · Posted

      ItuGlobal: Our Latest NETELLER VIPs 2025 ITU GLOBAL VIP Members’ Rewards Every calendar year, we choose 2 customers to become our VIPs. They’ve permanently special status with us and they can fund/withdraw Neteller through us, at parallel market rates, whether they open brokerage accounts through us or not.   These are people who funded with the highest amount of Neteller, and who also withdrew the highest amount of Neteller through us.  They would be announced in January each year and added to our list of VIPs. ItuGlobal: Our Latest NETELLER VIPs 2025 Adetoye Oyebanji Babalola: Adetoye O. has started selling large quantities of Neteller to us since the very beginning of our company’s existence. He also sold Perfect Money to us many times, when PM was still available in Nigeria. Besides, he has given us a lot of helpful business advice, which has proven to be invaluable to us. He deserves to become our VIP. Isiaka Adekunle Mohammed: He is a constant buyer. Buying e-currencies and also funding his Instaforex account through us. We thank Isiaka A. for his trust in us and wish him the best in everything he does. Abiodun Lawanson: This is an avid buyer and seller of Neteller. He buys and makes profits and sells back to us. Sometimes when we are not online, he will send an offline message and we will process his order once we come back online. He has thus become our VIP. Source: Ituglobalfx.com.ng  
    • analyst75
      The best way to avoid scammers

      By analyst75 · Posted

      The best and the most sure-fire way to avoid all these forms of nonsense is NEVER to send any money to anyone, no matter the circumstances they claim... Even your closest family members.   Whatever they claim will happen to them, let it happen.   There is nothing new under the sun...   You need to be extremely cruel.... Never send anything of value to anybody, no matter what they claim, even if they claim death.   If you can follow this GOLDEN RULE, you will avoid a lot of regrets, heartaches and disappointments from all areas.   I send money only to people I have promised before.... Or someone I am seeing face-to-face... Or someone I have confirmed beyond reasonable doubts from external/independent sources that they really need the money.   Otherwise, nobody under this heaven can come out of blue (unless my parents or wife), even my siblings and request money.   Over 90% of requests for financial assistance and are fraudulent.   After all, if you die today... The scammers (even in the family) will continue to live without you.   Those who are merciful, kind-hearted and soft-hearted are the easy preys and targets of these scoundrels - 419 scammers.   They like gullible people and hate tough/cruel people.   Do not allow anyone to cause you to feel guilty for what you don’t do… Those dubious people want to make you feel guilty for not helping. But you don’t need to feel guilty as long as you’re not the cause of their problems or the issues they have.   It is better to lose customers/friends/family members/anyone's goodwill and keep your money, than to lose their goodwill and also lose your money.   Because that is what will happen at last... I have lost count of how many people that are currently regretting giving out loans, just because they want to retain goodwill.   When you're trying to please people, you end up displeasing yourself... And you will discover that those who are encouraging you to be kind and generous are themselves wicked and stingy.   Esin o dede l’oro... Araye lo ko esin loro. (It's humans being that taught the horse how to be cruel).   The best way to avoid falling for scam is NEVER to send anything of value to anyone, no matter who the person is to you or how they relate to you on this planet...   And never try to get anything for free or reap where you don't sow and never try to get rich quickly.   Follow this: You will escape/avoid all scams, lies, pretenses, fakeries, headaches, sorrow, regrets, high BP, later in your life.   Ignore this rule at your own PERIL.   Have a nice day. PS: And scammers will be using AI also for impersonations, phishing attempts and deepfake tricks. Just delay indefinitely and make independent calls, research and investigation before you part with anything of value. If you can't go through the rigors, just ignore the deals. I hope the Western World will soon pass legislation to regulate AI and deal with those who use it for evil.  To get free, winning trading signals, please visit: https://t.me/predictmag 
    • Stocks4life
      Breakout and Swing Stock Ideas

      By Stocks4life · Posted

      C Citigroup stock watch, pullback to the 68.43 gap support area, with bullish indicators at https://stockconsultant.com/?C
    • Stocks4life
      Breakout and Swing Stock Ideas

      By Stocks4life · Posted

      HDSN Hudson Technologies stock, strong rally, watch for a bottom breakout at https://stockconsultant.com/?HDSN
    • Stocks4life
      Breakout and Swing Stock Ideas

      By Stocks4life · Posted

      GLD SPDR Gold Shares ETF watch for a top of range breakout above 273.3 at https://stockconsultant.com/?GLD
×
×
  • Create New...

Important Information

By using this site, you agree to our Terms of Use.

  I accept