Multiple Profit Targets for Multiple Contracts

[palmcarl 10]

Hello,

I am a total easylangguage newbie and try to figure out how to scale out a trade in a trading strategy.

 

My system should buy e.g. 3 contracts and sell 1 contract at various Dollar Profit targets.

 

I tried it this way:

 

if condition1 then begin 

Buy ( "Firstcontract" ) 1 contract next bar at market;
SetStopContract;
SetProfitTarget(25);

Buy ( "Secondcontract" ) 1 contract next bar at market;
SetStopContract;
SetProfitTarget(100);

Buy ( "Thirdcontract" ) 1 contract next bar at market;
SetStopContract;
SetProfitTarget(200);

end;

 

The problem is that the above code will just buy 1 contract and only execute the 1 profit target for that contract.

 

How could I get 3 contracts with three different profit targets being bought?

Would be great if anybody could help me.

[tradelink 10]

Ok well the reason it's only executing one profit target per contract is that those EasyLanguage statements are per strategy, not per signal. So you can only have one of those commands per strategy (this is for stop and profit targets).

 

As to why it's only sending one buy order... this seems strange to me. Although in theory since your buy signals are all being sent under the same condition, there is no reason they should be seperate. So you might try :

 

Buy 3 contracts at next bar at market

 

instead of 3 'buy 1 contracts' statements.

 

in terms of having multiple profit targets, you should be able to do that still... you just wouldn't want to use easylanguage functions. you'd want to check your openpl yourself, and then close the desired amount of trade. eg, something like :

 

if ((GetPositionOpenPL / GetPositionQuanity > profittarget3 ) && (profittarget3HIT==0))

then begin

Sell 1 contract at next bar at market

profittarget3HIT = 1

end

 

and so on for each target. vicea verca if you wanted to 'tier' stops/exits in the same way.

 

Sorry my easylanguage is a little rough, but the function names and general syntax should be right. You'd also have to make sure that GetPositionQuantity was not zero in the above example. Hopefully you get the idea, and you found this helpful.

[bakrob99 11]

In order to allow additional contracts to be added to the first order you have to select the option to allow "Pyramiding" in the Strategy Properties format box.

[swansjr 10]

Hello,

I am a total easylangguage newbie and try to figure out how to scale out a trade in a trading strategy.

 

My system should buy e.g. 3 contracts and sell 1 contract at various Dollar Profit targets.

 

I tried it this way:

 

if condition1 then begin 

Buy ( "Firstcontract" ) 1 contract next bar at market;
SetStopContract;
SetProfitTarget(25);

Buy ( "Secondcontract" ) 1 contract next bar at market;
SetStopContract;
SetProfitTarget(100);

Buy ( "Thirdcontract" ) 1 contract next bar at market;
SetStopContract;
SetProfitTarget(200);

end;

 

The problem is that the above code will just buy 1 contract and only execute the 1 profit target for that contract.

 

How could I get 3 contracts with three different profit targets being bought?

Would be great if anybody could help me.

 

 

If I understand you correctly I think this is what you are looking for:

 

if condition1 then Buy ( "Go Long" ) 3 contracts next bar at market; 


If ( CurrentContracts = 3) Then SetProfitTarget( Target_1 )
Else If ( CurrentContracts = 2 ) Then SetProfitTarget( Target_2 )
Else SetProfitTarget( Target_3 );

SetStopLoss( StopLoss );

 

 

Jeff

[swansjr 10]

If I understand you correctly I think this is what you are looking for:

 

if condition1 then Buy ( "Go Long" ) 3 contracts next bar at market; 


If ( CurrentContracts = 3) Then SetProfitTarget( Target_1 )
Else If ( CurrentContracts = 2 ) Then SetProfitTarget( Target_2 )
Else SetProfitTarget( Target_3 );

SetStopLoss( StopLoss );

 

 

Jeff

 

 

Let me correct that:

 

If ( condition1 ) Then Buy ( "Go Long" ) 3 contracts next bar at market; 

If ( CurrentContracts = 3) Then  Sell ("Target 1") next bar at EntryPrice+Target_1 limit
Else If ( CurrentContracts = 2 ) Then Sell ("Target 2") next bar at EntryPrice+Target_2 limit
Else Sell ( "Target 3") next bar at EntryPrice+Target_3 limit;


SetStopLoss( StopLoss );

[bubba 10]

just curious..

did the OP resolve this issue?

the thread apparently just stopped

 

i've made a few attempts at this (scalable profits), but none lately.

it seemed difficult..

[swansjr 10]

I'm actually home so I was able to verify the following code. It's a simple moving average crossover system that uses three targets.

 

Input:
   Price( Close ),
   StopLoss$(300),
   LT_Length( 34 ),
   ST_Length( 13 ),
   Target_1(25),
   Target_2(50),
   Target_3(100);

Variables:
  LT_SMA(0),
  ST_SMA(0),
  Counter(0);


LT_SMA = Average( Price, LT_Length );
ST_SMA = Average( Price, ST_Length );

If ( ST_SMA crosses over LT_SMA ) Then Buy ( "Long" ) 3 contracts next bar at market
Else If ( ST_SMA crosses under LT_SMA ) Then SellShort ( "Short" ) 3 contracts next bar at market;

If ( MarketPosition = 1 ) Then
Begin
If ( CurrentContracts = 3) Then Sell ("LT 1") 1 contract next bar at EntryPrice+Target_1 limit
Else If ( CurrentContracts = 2 ) Then Sell ("LT2")1 contract next bar at EntryPrice+Target_2 limit
Else Sell ( "LT 3") next bar at EntryPrice+Target_3 limit;
End
Else If ( MarketPosition = -1 ) Then
Begin
If ( CurrentContracts = 3) Then BuyToCover ("ST 1") 1 contract next bar at EntryPrice-Target_1 limit
Else If ( CurrentContracts = 2 ) Then BuyToCover ("ST 2") 1 contract next bar at EntryPrice-Target_2 limit
Else BuyToCover ( "ST 3") next bar at EntryPrice-Target_3 limit;
End;


SetStopLoss( StopLoss$ );

[bubba 10]

well..

let's see, maybe i'm just too slow but...

what happens if you enter a long position; you hit 1st target so you now are long 2 contracts

 

then..

you get a signal to enter short position (sell 3 contracts)

what's your position now?

Edited March 21, 2009 by bubba

[swansjr 10]

Given your example, it is my understanding TradeStation "knows" to sell short 5 contracts thus brining you to 3 contracts short.

[bubba 10]

thanks much..

 

i'll play with it and see.

i use TS 2000i, so my results may vary

[bubba 10]

nope.. it needs edits for 2000i apparently.

(i'm very much a self-taught novice)

 

no biggie,

 

it's just i've always wanted to build some systems with scalable profits.

i think it could smooth my equity curve a bit, but so far, i just can't prove it..

 

thanks for your feedback

[bubba 10]

re-wrote it a bit to fit 2000i. it may be working.

i had thought the scaling targets were monetary settings when i placed it on an ES chart, but i finally figured out it was reading ES points. lol

i'll report back if i discover more.. thx

 

bah.. something's not right.

oh well, i'll keep fiddling

Edited March 22, 2009 by bubba

[bubba 10]

got close but not quite. long positions exit properly i think. shorts dont scale, just exit at final target.

Input: Price( Close ), s(200), LT_Length( 34 ), ST_Length( 13 ),
Target_1(25), Target_2(50), Target_3(100);
Variables: LT_SMA(0), ST_SMA(0), Counter(0),t1(0);
setstoploss(s);
LT_SMA = Average( Price, LT_Length );
ST_SMA = Average( Price, ST_Length );
If ( ST_SMA crosses over LT_SMA ) Then Buy ( "Long" ) 3 contracts next bar at market; 
If ( ST_SMA crosses under LT_SMA ) Then Sell ( "Short" ) 3 contracts next bar at market;
If ( MarketPosition = 1 ) Then Begin
If ( CurrentContracts = 3) then 
exitlong ("LT 1") 1 contract next bar at EntryPrice+Target_1 limit
else
If ( CurrentContracts = 2 ) Then 
exitlong ("LT2")1 contract next bar at EntryPrice+Target_2 limit
else
exitlong ( "LT 3") next bar at EntryPrice+Target_3 limit;
end;
If ( MarketPosition = -1 ) Then Begin
If ( CurrentContracts = -3) then 
exitshort ("ST 1") 1 contract next bar at EntryPrice-Target_1 limit
else
If ( CurrentContracts = -2 ) Then 
exitshort ("ST2") 1 contract next bar at EntryPrice-Target_2 limit
else
exitshort ( "ST 3") next bar at EntryPrice-Target_3 limit;
end;

 

i'll post a capture for you to see in a sec

Edited March 22, 2009 by bubba

[bubba 10]

on the left, you can see a long entry, then scaling exits. looks ok..

on the right, a short entry, no scaling, then exits at final target.

i'm afraid i don't see the error...

 

**i expect there ISN'T an error - but a limitation with 2000i (or bug)

hope i'm wrong

Edited March 22, 2009 by bubba

[sevensa 10]

on the left, you can see a long entry, then scaling exits. looks ok..

on the right, a short entry, no scaling, then exits at final target.

i'm afraid i don't see the error...

 

Your short code has the following two lines:

 

If ( CurrentContracts = -3) then

exitshort ("ST 1") 1 contract next bar at EntryPrice-Target_1 limit

else

If ( CurrentContracts = 2 ) Then

exitshort ("ST2") 1 contract next bar at EntryPrice-Target_2 limit

 

 

The first if check for -3 contracts and the 2nd one for 2 contracts. You are missing the - sign in the 2nd if.

[bubba 10]

thank you, i actually had caught that error, but found it wasn't the issue. i just now checked the original code that swan had posted and noted that i had a discrepancy. i changed it, and it worked!

here it is:

 

for the short contracts i had used-

If ( CurrentContracts = -3) then ...

but it should be

If ( CurrentContracts = 3) then ...

seems illogical huh.. told ya ima n00b

here's the correct (i believe) code:

Input: Price( Close ), sloss(200), LT_Length( 34 ), ST_Length( 13 ),
Target_1(25), Target_2(50), Target_3(100);
Variables: LT_SMA(0), ST_SMA(0), Counter(0);
setstoploss(sloss);
LT_SMA = Average( Price, LT_Length );
ST_SMA = Average( Price, ST_Length );
If ( ST_SMA crosses over LT_SMA ) Then Buy ( "Long" ) 3 contracts next bar at market; 
If ( ST_SMA crosses under LT_SMA ) Then Sell ( "Short" ) 3 contracts next bar at market;
If ( MarketPosition = 1 ) Then Begin
If ( CurrentContracts = 3) then 
exitlong ("LT 1") 1 contract next bar at EntryPrice+Target_1 limit
else
If ( CurrentContracts = 2 ) Then 
exitlong ("LT2")1 contract next bar at EntryPrice+Target_2 limit
else
exitlong ( "LT 3") next bar at EntryPrice+Target_3 limit;
end;
If ( MarketPosition = -1 ) Then Begin
If ( CurrentContracts = 3) then 
exitshort ("ST 1") 1 contract next bar at EntryPrice-Target_1 limit
else
If ( CurrentContracts = 2 ) Then 
exitshort ("ST2") 1 contract next bar at EntryPrice-Target_2 limit
else
exitshort ( "ST 3") next bar at EntryPrice-Target_3 limit;
 end;

Edited March 22, 2009 by bubba

[bubba 10]

the updated chart

 

appreciate the help,

you 'made' me re-check it

Edited March 22, 2009 by bubba

[bubba 10]

I made this exit signal for Tradestion2000i. It allows you to scale out and move stops up. I think it works properly, but welcome suggestions or improvements. Of course, without the contributions from others on this thread, I would have been clueless. I included "Var: counter(0)" from the original code Swansjr provided. What it does exactly, I'm not sure..

The stops are $ values. Targets are Point values.

Input: s(1000),s1(100),Target_1(25),Target_2(50), Target_3(100);
Variables:Counter(0); 

If ( MarketPosition = 1 ) Then Begin
If ( CurrentContracts = 3) then 
exitlong ("LT 1") 1 contract next bar at EntryPrice+Target_1 limit
else
SetStopLoss(s);{inital $ stop}
If ( CurrentContracts = 2 ) Then 
exitlong ("LT2")1 contract next bar at EntryPrice+Target_2 limit 
else
SetStopLoss(s1); {tighter $ stop after 1st target is hit}
exitlong ( "LT 3") next bar at EntryPrice+Target_3 limit;
end;
If ( MarketPosition = -1 ) Then Begin
If ( CurrentContracts = 3) then 
exitshort ("ST 1") 1 contract next bar at EntryPrice-Target_1 limit
else
SetStopLoss(s);	
If ( CurrentContracts = 2 ) Then 
exitshort ("ST2") 1 contract next bar at EntryPrice-Target_2 limit
else
SetStopLoss(s1); 	
exitshort ( "ST 3") next bar at EntryPrice-Target_3 limit;
 end;

Edited March 22, 2009 by bubba

[bakrob99 11]

well..

let's see, maybe i'm just too slow but...

what happens if you enter a long position; you hit 1st target so you now are long 2 contracts

 

then..

you get a signal to enter short position (sell 3 contracts)

what's your position now?

 

Your Strategy will NOT be doing a Stop and Reverse entry because you have a test for Marketposition. So your marketposition if Long (per your example) will be = 1 and the Short will not trigger.

[bubba 10]

not to be argumentative.. but to investigate your point.

here's today's trades from Swansjr's strat. it certainly looks to be handling the contracts appropriately. what am i missing?

[bubba 10]

yup - i concede, it's not working properly. will re-visit when time permits.

 

could be my edits to the code tho.. (the setstoploss)

 

this system has the scaling exit signal i posted here previously.

[bubba 10]

removed the exit signal which tightened stops when scaling out and applied a standard stop. seems to resolve the glitch.

 

exactly what was happening i'm not sure.

[ephi144 10]

exitlong and exitshort keywords are not working for me in the strategy.

i can do sell and buy.

 

i am on 8.4

 

anyone know what could cause this?

 

thanks

[Tams 20]

latest keyword matching:

 

BUY... means to enter a LONG position

SELL... means to close a LONG position

(you cannot go short with a SELL keyword)

 

SELLSHORT... means to enter a SHORT position

BUYTOCOVER... means to close a SHORT position.

 

 

 

exitlong and exitshort are old keywords and are not supported in the latest versions.