Easylanguage and Script Help

[darknite999 10]

Hello, (Apologies in advanced if I have posted this in the wrong place)

 

I'm new to easylanguage scripting and was wondering if someone could help me please.

 

I want to write a script that will show me, on an upward trend of 3 or more candlesticks, the highest high of that trend. The new high must be a red candelstick and the trend must contain at least one green candle.

 

How would I go about doing this please?

 

Thanks for you help in advanced,

Darknite.

[zdo 20]

please spec out a little bit more about what you mean by

1 "upward trend".

is the lowest low >= 4 bars ago or

must the trend members lows all be higher than previous low or

_______ ???

 

thx

[darknite999 10]

 

I hope this sums it up

 

Once again thanks for your help it's much apreciated.

 

Cheers,

Darknite

[BlowFish 10]

IF C[1]>C[2] and c[2] > C[3] and C[3] > C [4] and H > H [1] and C < O then

plot1 (h+1,"High")

else

noplot1;

 

Set to plot a dot, it should plot over the high on bar close. You can but your own logic in quite simply. The number in square brackets [n] signifies n bars ago. Haven't tested it as I typed it straight into the post. I'm sure BlueRay wll correct it if I am wrong

[Blu-Ray 10]

IF C[1]>C[2] and c[2] > C[3] and C[3] > C [4] and H > H [1] and C < O then

plot1 (h+1,"High")

else

noplot1;

 

Set to plot a dot, it should plot over the high on bar close. You can but your own logic in quite simply. The number in square brackets [n] signifies n bars ago. Haven't tested it as I typed it straight into the post. I'm sure BlueRay wll correct it if I am wrong

 

hehehe....nice one Blowfish. :o

 

The only thing I would add to the line would be :

 

H > H[2] and H > H[3] and H > H[4]

 

Just incase one of the previous candles had a higher high leaving a long shadow. As with Blowfish, I've never tested it, but give it a try and let us know how you get on.

 

Cheers

 

Blu-Ray

[darknite999 10]

Great!!

 

It worked just about so I had a look through what you told me and made a few adjustments so instead it was this:

 

IF C[1]>C[2] and H > H [1] and H > H[2] and C < O then

plot1 (h+1,"High")

else

noplot(1);

 

How would I do this for a strategy please?

 

how do I add a stoploss and tell it to sell and buy back 30 points below...

 

Once again greatly apreciated and thanks for your help,

Darknite.

[BlowFish 10]

I have never used a strategy in TS so I will defer to BlueRay Hopefully will learn something too. There are a bunch of reserved words to buy sell etc. that I guess would go in instead of plot.

 

Easylanguage really is pretty easy (IMHO) and a bit of hands on will get you there in no time at all.

 

Perhaps look at one of the sample strategies to see how it hangs together. Im sure there must be one for a moving average Xover or something similar.

 

Be interested how it pans out for you.

[darknite999 10]

Cheers,

 

If anyone else could help me please that would be brilliant

 

In the mean time i'll see if I can find a sample strategy that has those commands i'm looking for (haven't found so far and the websites on google are running out :P)

 

All I need to know is how to sellshort and I think it's buy to cover 30 points below...

 

Grrrrr difficult :P

 

Cheers.

[Blu-Ray 10]

Darknite

 

It would depend on your particular entry and stoploss criteria, Here's a strategy code I've done, but I've based it on entry 1 tick below the low of the reversal bar, with the stoploss being x amount of ticks above the high of the reversal bar ( I've made that section as an input, so you can decide ).

 

Inputs:

ProfTarget(30),StopLoss(1); { These inputs are in number of ticks }

 

Vars:

ShortEntry(0), Permission(0), Mintick(0), mystop(0), MP(0);

 

MP = marketposition;

Mintick = minmove/pricescale;

 

 

Condition1 = C[1]>C[2] and H > H [1] and H > H[2] and C < O;

 

 

if condition1 and MP = 0 then begin

ShortEntry = Low - (1*mintick);

mystop = High + (Stoploss*mintick);

permission = 1;

end;

 

if permission = 1 then begin

SellShort next bar at ShortEntry Stop;

Permission = 0;

end;

 

if mp = -1 then begin

buytocover ("ProfitTarget") next bar at ShortEntry - (ProfTarget*mintick) limit;

buytocover ("StoppedOut") next bar at mystop stop;

end;

 

If you have exact entry and exit criteria different from above, just let me know and I'll amend it for you.

 

Hope this helps

 

Blu-Ray

[darknite999 10]

If you have exact entry and exit criteria different from above, just let me know and I'll amend it for you.

 

Hope this helps

 

Blu-Ray

 

 

Hey,

 

Thanks very much for your help.

 

I would like to place a stop loss 2 ticks above the high and sellshort 1 tick below the low

 

i want to buy to cover 30 below where I came in.

 

Cheers and once again thank you,

Darknite.

[Blu-Ray 10]

Hey,

 

Thanks very much for your help.

 

I would like to place a stop loss 2 ticks above the high and sellshort 1 tick below the low

 

i want to buy to cover 30 below where I came in.

 

Cheers and once again thank you,

Darknite.

 

No Probs, just change the input in stoploss from 1 to 2 and the rest is already in the above code.

 

Cheers

 

Blu-Ray

[darknite999 10]

 

Cheers,

 

I forgot to mention one thing and I don't know if it is possible althought I'll ask.

 

Is it possible to identify a pattern on one chart and then carry the order out on another one.

 

So, as simply as I can explain

 

Using a strategy, find the pattern on the chart and carrying out the order on another chart?

 

Cheers,

Darknite.

[Blu-Ray 10]

Yes it is possible, for instance if you see the signal on a 5 min chart but want it executing via a 1min chart, yes just let me know what you want.

 

The only thing is if it's a minute / tick chart combination, then thats beyond me, as it's requires ADE ( All Data Everywhere ) and I'm not clued up on it yet.

 

Cheers

 

Blu-Ray

[darknite999 10]

Hi,

 

Sorry what I meant was I want the strategy to find the setup on $indu for example and take the trade on DIA(diamonds).

 

How do i go about doing this?

 

Also on the script what does Minprice/Pricescale mean. Please could you break it down for me?

 

Cheers,

darknite

Edited March 27, 2008 by darknite999

[darknite999 10]

Oh, and also what should my "Maximum number of bars study will reference" under the strategy propeties - back-testing resolution be? What does this mean, it seems to affect my what trades it shows :S

 

Help

 

Thanks again,

Darknite.

[Blu-Ray 10]

Hi,

 

Sorry what I meant was I want the strategy to find the setup on $indu for example and take the trade on DIA(diamonds).

 

How do i go about doing this?

 

Also on the script what does Minprice/Pricescale mean. Please could you break it down for me?

 

Cheers,

darknite

 

Darknite

 

All you would do is set up $indu at data2 within the strategy, easy enough to do, but would need to know if your entry, stoploss and target are all based on $indu or DIA.

 

Minprice/Pricescale is easylanguages way of determining what value a minimum tick is worth. It's easier doing it that way so if you wanted to put the strategy into a different market with a different tick value, then you can still choose your target & stoploss via tick amount.

 

Cheers

 

Blu-Ray

[Blu-Ray 10]

Oh, and also what should my "Maximum number of bars study will reference" under the strategy propeties - back-testing resolution be? What does this mean, it seems to affect my what trades it shows :S

 

Help

 

Thanks again,

Darknite.

 

Just set it at 50-100, ideally the lowest amount it will let you do. What it means is that the strategy will reference, for example 50 bars, before it will start to calculate the strategy.

 

Hope this helps

 

Blu-Ray

[darknite999 10]

Cheers it's all starting to make sence now!!

 

So what would I have to do...

 

Basically When I find the candle pattern on, for example (again), $indu I want to take the trade on DIA with the same stoploss (2 above the high) and start the trade 1 tick below and make a profit of 30 ticks...

 

What would I need to add/change to complete the script

 

You've been so much help,

Cheers. Darknite.

[Blu-Ray 10]

Darknite

 

You would need to set up $indu at data2 within the strategy. If you want, send me a PM with your email address and I'll code it up for you and also send a tradestation workspace with the chart and strategy already setup.

 

Also let me know what timeframe you want them in ( same ? ).

 

I'm off to sleep :sleep: now as it's past midnight here, so I'll sort it out tomorrow.

 

Cheers

 

Blu-Ray

[darknite999 10]

I'm from Britain too

 

Same I'm off to bed i'll sort it out tomorrow.

 

Cheers,

Darknite.

[thrunner 10]

Blu-Ray, you've got my vote for the saint of the week :o

Note to Soultrader, please consider a poll for the most helpful member of the week/month and the most thankful member as well. I think it will promote civility even more than the high standards we already have here at TL.

 

Here is an attempt at BR's coded strategy for darknite on two data series:

Unfortunately, I think the price action that darknite posted is usually a little bullish and the strategy is usually in the red (note the time frame for $NDX.X is reduced to 15 min to reduce the number of trades. You will also need realtime subscription to both symbols. Workspace and strategy eld in zip file, for 8.3.1419 and above :

 

 

 

Inputs:
ProfTarget(30),StopLoss(1 ); { These inputs are in number of ticks }

Vars:
ShortEntry(0), Permission(0), Mintick(0), mystop(0), MP(0);

MP = marketposition;
Mintick = minmove/pricescale;

Condition1 = C[1] data2 >C[2] data2 and H data2 > H [1]data2 and H data2 > H[2] data2 and C data2 < O data2;

if condition1 and MP = 0 then begin
ShortEntry = Low - (1*mintick);
mystop = High + (Stoploss*mintick);
permission = 1;
end;

if permission = 1 then begin
SellShort next bar at ShortEntry Stop;
Permission = 0;
end;

if mp = -1 then begin
buytocover ("ProfitTarget") next bar at ShortEntry - (ProfTarget*mintick) limit;
buytocover ("StoppedOut") next bar at mystop stop;
end;

_3barPB_2.zip

[Soultrader 12]

Great idea thrunner. Always wanted to do something like it but was never sure of the format of things. I will get to work on it.

[Blu-Ray 10]

thrunner,

 

Thanks for doing that, it's much appreciated.

 

James,

 

Would it be possible to add "tsw" ( Tradestation Workspace ) to the list of attachments, it might make things easier in the future.

 

Cheers

 

Blu-Ray

[darknite999 10]

Wow!

 

Thanks so much!

 

I now only have one problem.

 

For some reason when using the showme all the points it plots are correct but when using the strategy it only show about 80% of the trades that it should do. Is there something wrong?

 

Is it possible that I can buy back 30 ticks below the entry on the same bar (if the low goes down that far) if not then the 1st bar that the low gets low enough to buy back at 30 ticks below the entry?

 

One final thing (I think ) How do I change to script so it won't sell anything when there is 1 hour till closing and then start again the next morning? (To prevent holding trades when the market has closed)

 

Blu-Ray - I have to hand it to you and everyone else that has been helping me. I appreciated it so much. You don't understand the stress it was causing me that no one could help me. Then I found this forum

 

Cheers,

Darknite.

Edited March 28, 2008 by darknite999

[Blu-Ray 10]

Wow!

 

Thanks so much!

 

I now only have one problem.

 

For some reason when using the showme all the points it plots are correct but when using the strategy it only show about 80% of the trades that it should do. Is there something wrong?

 

One final thing (I think ) How do I change to script so it won't sell anything when there is 1 hour till closing and then start again the next morning? (To prevent holding trades when the market has closed)

 

Blu-Ray - I have to hand it to you and everyone else that has been helping me. I appreciated it so much. You don't understand the stress it was causing me that no one could help me. Then I found this forum

 

Cheers,

Darknite.

 

With regards to it only taking 80% of the trades as per the show me, I would guess the next bar did not take out the low of the signal bar, as this strategy only sends the sellshort order on the very next bar.

 

Here's the revised code with an endtime added as an input:

 

Inputs:

ProfTarget(30),StopLoss(1 ),endtime(1900);

 

Vars:

ShortEntry(0), Permission(0), Mintick(0), mystop(0), MP(0);

 

MP = marketposition;

Mintick = minmove/pricescale;

 

Condition1 = C[1] data2 >C[2] data2 and H data2 > H [1]data2 and H data2 > H[2] data2 and C data2 < O data2;

 

if condition1 and MP = 0 and time < endtime then begin

ShortEntry = Low - (1*mintick);

mystop = High + (Stoploss*mintick);

permission = 1;

end;

 

if permission = 1 then begin

SellShort next bar at ShortEntry Stop;

Permission = 0;

end;

 

if mp = -1 then begin

buytocover ("ProfitTarget") next bar at ShortEntry - (ProfTarget*mintick) limit;

buytocover ("StoppedOut") next bar at mystop stop;

end;

 

Also add either of these two lines to the end of the code....

 

This one will close your position if you've got an open position and it's after the endtime. Note: It will close the position whether it's in profit or loss.

 

if mp = -1 and time > endtime then buytocover next bar at market;

 

Or the second one will set the exit on the close of the session, again whether it's in profit or loss. ( But note this should only be used on historical simulations, as depending on the instrument it can lead to your exit being taken on the open of the next day)

 

if mp = -1 and time > endtime then setexitonclose;

 

 

Hope this helps

 

Blu-Ray